Shell Programming and Scripting

Both file1.txt and file2.txt have line separators that are <carriage-return><newline> character pairs instead of just <newline> and neither of these files end with a <newline> character. So, by definition, they are not text files. Since the last lines in file1.txt and file2.txt were incomplete lines, id "At3g02190" might not have been processed correctly (if it had appeared in file3.txt) and code "S" (if it had been the code for any id that was being processed) might not have been handled as desired.

The following script adds trailing <newlines> characters to each input file (in the echo loop at the start of the script) and removes any <carriage-return> characters found in the input (using gsub()) and any empty lines (which were already present in file2.txt and may now have been created by the echo loop) while processing the input files. The logic is similar to Yoda's script, but gets rid of some processing by using a more complex ERE for the field separator:

Code:

#!/bin/ksh
# Add trailing newlines to the input files.
for i in 1 2 3
do      echo >> file$i.txt
done
awk -F '[[]|] |th:  | *$' '
BEGIN { OFS = "|" }
{       # Get rid of any carriage returns characters in the input files.
        gsub(/\r/, "")
}
/^$/ {  next }  # Skip empty lines.
FNR == 1 { f++ }
f == 1 {# Gather codes for id from 1st file:
        if($0 ~ /^[[]/) {# If line start with "[", it contains the code
                c = substr($2, 1, 1)    # Discard trailing "R", if present.
                next
        }
        code[$2] = c    # Otherwise, we have an id; save the code for this id.
        next
}
f == 2 {# Gather description for each code from 2nd file:
        if(NF == 1)     # Save code group heading.
                h = $0
        else            # Save code description.
                desc[$2] = $3 OFS h
        next
}
{       # We must be looking at the 3rd file.  Print description for given id.
        print $1, code[$1], desc[code[$1]]
}' file[123].txt

I use the Korn shell, but any shell that accepts basic Bourne shell syntax will work with this script. If you want to run this on a Solaris/SunOS system, change awk to /usr/xpg4bin/awk, /usr/xpg6/bin/awk, or nawk.

The output produced with the sample inputs is:

Code:

At1g53930|O|Posttranslational modification, protein turnover, chaperones|CELLULAR PROCESSES AND SIGNALING
At2g36170|J|Translation, ribosomal structure and biogenesis|INFORMATION STORAGE AND PROCESSING

which seems to match what was requested except that there is no space character immediately after the last "|" in each line.