Shell Programming and Scripting

awk -F, '                                                                 # Set Field Separator as comma
FNR==NR{
      A["\""$1"\""]=$2                                                    # Define Array Named A with column one as index and column2 as its value of file1
      next
       }
       {
         for(i in A)                                                      # Start looping on array A
                 if($0~i)                                                 # If line contains index then following
                     R=A[i]
                     if(R && $0~/style/){                                 # If R is not empty and string style is found ?
                                        j++                               # Increment j
                                        if(j==2){                         # If j==2 that is just above </g>
                                                gsub(/#.*;/,"#"R";");     # Replace  style value
                                                R=j=""                    # Reset counter and R
                                               }
                                       }
        }1'  file1 file2

awk     'NR==FNR                {Arr[$1]=$2; next}
         ($2 in Arr)            {P=1; IX=$2}
         /<path/                {F=P}
         /style.*fill:#/ && F   {sub (/:#[^;]*;/, ":#" Arr[IX] ";")}
         /<\/g>/                {P=F=0}
         1
        ' FS=, file1 FS=\" OFS=\" file2

awk     'NR==FNR                {Arr[$1]=$2; next}                      # read file1: 2. fields into array Arr indexed by 1. field
                                                                        # work on file2 from here on field sparator: "
         ($2 in Arr)            {P=1; IX=$2}                            # if field 2 (id) has been recorded in Arr, keep that fact in P var; save $2 for index
         /<path/                {F=P}                                   # if path- section was entered, and id was matched, we (F)ound the right section
         /style.*fill:#/ && F   {sub (/:#[^;]*;/, ":#" Arr[IX] ";")}    # fill- pattern found AND correct section: modify (substitute command)
         /<\/g>/                {P=F=0}                                 # paragraph ended; reset all logical variables
         1                                                              # print all (modified or unmod.) lines in file2
        ' FS=, file1 FS=\" OFS=\" file2                                 # list files to work on and resp. field separators