Shell Programming and Scripting

Hi,

I have file1 like this:

Code:

a 64
b 66
c 67

and file2 like this:

Code:

@1234
1123
aabbcc
@5453
5543
ccba

I want to replace each letter of the third line in file2 with corresponding number in file1. So desired output is,

Code:

@1234
1123
646466666767
@5453
5543
67676664

I tried something like this but not working

Code:

awk 'NR==FNR{a[$1]=$2;next}{if(i in a) gsub(/i/,a[i]); print }' file1 file2

thanks in advance

Try:

Code:

awk 'NR==FNR{a[$1]=$2;next}!(FNR%3){n=split($0,x,"");$0="";for (i=1;i<=n;i++)$0=$0""a[x[i]]}1' file1 file2

Code:

awk 'NR==FNR{a[$1]=$2;next}{for (i in a) gsub(i,a[i]); print }' file1 file2

Thanks a lot, this is working. I didnt know how to use split function. Learned something today.

---------- Post updated at 08:09 PM ---------- Previous update was at 08:08 PM ----------

Some how this didnt work for me despite using backlashes after gsub. Thank you though.

Note: CarloM's suggestion should work with your sample, however the first variable used in the gsub command gets interpreted as an entended regular expression (ERE). So if your actual "file1" contains characters that have a special meaning in an ERE then it will not work.

( If it did not work for you with your sample input, then what is your OS / version and what did you mean by backslashes ?)

You cannot solve it by using backslashes, since these can also be used to introduce a special meaning to an ordinary character (for example n and \n) ..

--
Bartus11's suggestion relies on a particular (non-POSIX) awk extension so that an empty field separator (FS) means that each individual character becomes a separate field (it is only done here only on every third line, I don't understand why)

--
Also using the special case of null-string FS:

Code:

awk 'NR==FNR{A[$1]=$2; next}{for(i=1; i<=NF; i++)if($i in A) $i=A[$i]}1' file FS= OFS= file2

for other awks, one could try:

Code:

awk 'NR==FNR{A[$1]=$2;next}{s=x; for(i=1; i<=length; i++){c=substr($0,i,1); s=s (c in A? A[c]:c) } print s}' file1 file2