Shell Programming and Scripting

 
a,d,0.33
a,b,0.25
b,c,0.11

 
,a,b,c,d
a,1,0.25,0,0.33
b,0.25,1,0.11,0
c,0,0.11,1,0
d,0.33,0,0,1

 
awk 'BEGIN { FS =","; OFS="," }
w[$1,$2]=$3; w[$2,$1]=$3
<if i am right, both dimensions of indices should be already complete?>
END {
<first i have to write the column headers>
print OFS; for (i in sorted(w)) {print i OFS }; print "\n";
<now i want loop over the alphabetically sorted indices>
for (i in sorted(w)) {
print i OFS; for (j in sorted(w)) {
if (w(i,j) not defined) print 0;
else if (i==j) print 1;
else print w(i,j)
} print "\n" }
}' ADJlist.txt > ADJmatrix.txt

awk '
  BEGIN{
    FS=OFS=","
    h="a,b,c,d"
    n=split(h,F)
    print x,h
  }
  {
    A[$1,$2]=A[$2,$1]=$3
  }
  END{
    for(i=1; i<=n; i++) {
      s=F[i]
      for(j=1; j<=n; j++) s=s OFS (i==j ? 1 : A[F[i],F[j]]+0)
      print s
    }
  }
' file

awk '
  {
    A[$1,$2]=A[$2,$1]=$3
    if(!P[$1]++) F[++n]=$1
    if(!P[$2]++) F[++n]=$2
  }
  END{
    for(i=1; i<=n; i++) h=h OFS F[i]
    print h
    for(i=1; i<=n; i++) {
      s=F[i]
      for(j=1; j<=n; j++) s=s OFS (i==j?1:A[F[i],F[j]]+0)
      print s
    }
  }
' FS=, OFS=, file

 
gawk '
BEGIN { FS=OFS="," }  
{
    A[$1,$2]=A[$2,$1]=$3
    if(!P[$1]++) F[++n]=$1
    if(!P[$2]++) F[++n]=$2
  }
  END{
n = asort(F, G)     
for(i=1; i<=n; i++) h=h OFS G[i]
    print h
    for(i=1; i<=n; i++) {
      s=G[i]
      for(j=1; j<=n; j++) s=s OFS (i==j?1:A[G[i],G[j]]+0)
      print s
    }
  }
' file