Shell Programming and Scripting

Please help with this.. my file sizes exceed 40GB,,not possible to do manually.


I have a string in the 2nd column that has strings like 5M108N31M, 3S2M100N45M4S etc..the first column is a number.


There can be 0,1 or 2 number of S but only 1,2 Ms and only 1 N.
S only occurs at the beginning or at the end of the string.

I want to extract values corresponding to M,S,N

example for string 5M108N31M

S1=0 (since no S is present)
M1=5
N=108
M2=31

for the second string 3S2M100N45M4S

S1=3
M1=2
N=100
M2=45
S2=4

In the output the first column is (1st column in input+S1+M1)
In the output the second column is (1st column in input+S1+M1 + N )
M2 and S2 are not needed for the calculations.

Sample input

Code:

100 5M108N31M
100 3S2M100N45M4S

Sample output

Code:

105 213
105 205

try:

Code:

awk '{s=m=n=0}
/S/ {s=$0; sub("S.*","",s); sub(".*[A-Z ]","",s)}
/M/ {m=$0; sub("M.*","",m); sub(".*[A-Z ]","",m)}
/N/ {n=$0; sub("N.*","",n); sub(".*[A-Z ]","",n)}
{print $1+s+m, $1+s+m+n}
' input

something along these lines:
awk -f ritak.awk mySampleFile

where ritak.awk is:

Code:

{
  s=m=n=0

  match($2, "[0-9][0-9]*M")
  m=substr($2, RSTART, RLENGTH-1)

  match($2, "[0-9][0-9]*S")
  s=substr($2, RSTART, RLENGTH-1)

  match($2, "[0-9][0-9]*N")
  n=substr($2, RSTART, RLENGTH-1)

  print $1+s+m, $1+s+m+n
}

Try:

Code:

awk -F'[^0-9]*' '
  { 
    split($0,L,/[0-9]*/)
    for(i=NF-1; i>1; i--) A[L[i+1]]=$i
    n=$1 + A["S"]+A["M"]
    print n, n+A["N"]
    A["S"]=x
  }
' file

excellent. thanks a lot !!