Shell Programming and Scripting

Hello all,

I got some time duration data like below and I want to compute the cumulative elapsed time. The data is in MM:SS.SS format. I got struck with logic on what to do when it changes from 59:59.ss to 00:00.ss.

Code:

59:59.4
59:59.6
59:59.9
00:00.1
00:00.4
00:00.6
00:00.9

I need the below cumulative elapsed time(in seconds) as output

Code:

0
0.2
0.5
0.7
1.0
1.2
1.5

In reality I have millions of rows in my file.
Any help on this is appreciated.
Thanks
Sidda

Code:

awk -F ':'   'FNR==1 {minutes=$1; old=$1; sec=$2; start=(minutes*60) +sec}
                {$old!=$1} {minutes++; old=$1}
                {print  (minutes*60 + $2) - start } ' infile

Start with that.

Code:

$ awk -F ":" 'FNR==1{ti=$1*60+$2}
{s=0}
$1=="00"{s=3600;}
{print ($1*60+s+$2-ti)}' file

0
0.2
0.5
0.7
1
1.2
1.5

With a million lines of input (assuming adjacent timestamps represent monotonically increasing times [even though only minutes and seconds are given] and assuming that there is at least one entry every hour), the time covered is somewhere between 27 hours and 42,000 days. The script provided by pamu assumes that all timestamps to be processed occur in a single one hour period and prints some elapsed times as negative values).

Jim McNamara said his script was a starting point. But, it looks like he didn't test it with your sample data. (It has an extraneous {$ and } and doesn't check for cases where the minutes are the same as the previous line but the seconds are less than the previous line.)

If my assumptions about your timestamps are correct, I think the following awk script comes closer to doing what you want. However, when the number of seconds reaches 60, it will print MM:SS.S; when the number of elapsed minutes reaches 60, it will print HH:MM:SS.S instead of just HH:SS.S; and when the number of elapsed hours reaches 24, it will print Days:HH:MM:SS.S in addition to the number of elapsed seconds:

Code:

awk -F: '
function tp(seconds,    d, h, m, s) {
        if(seconds < 0) {
                s = seconds + 3600
                h = hours - 1
        } else {
                s = seconds
                h = hours
        }
        m = int(s / 60)
        s = s % 60
        d = int(h / 24)
        h = h % 24
        if(d + h + m) printf("%-20.1f ", ((((d * 24) + h) * 60) + m) * 60 + s)
        if(d) printf("%d:", d)
        if(d + h) printf("%02d:", h)
        if(d + h + m) printf("%02d:", m)
        printf("%04.1f\n", s)
}
NR == 1 {
        hours = 0
        start = (minutes = $1) * 60 + (seconds = $2)
}
{       if(minutes > $1 || (minutes == $1 && seconds > $2)) hours++
        tp((minutes = $1) * 60 + (seconds = $2) - start)
}' data

This can obviously be significantly simplified if you really just want to print the elapsed seconds (without splitting it into days, hours, minutes, and seconds).

As always, if you are using a Solaris/SunOS system, use /usr/xpg4/bin/awk, /usr/xpg6/bin/awk, or nawk instead of awk.

Thanks Don, Pamu and Jim,

All the scripts worked well.
Also I forgot to mention the elapsed time in my file with million rows actually varies from few seconds to few hours(based on another context data column values).
So the script provided by Don is really great and helpful in future also in case if I need to calculate elapsed time with days.

Sidda

That's an incredibly good script provided.

Any chance you might want to change the log file format to include "number of seconds since the epoch"? Then you would not have the rollover problem.