Shell Programming and Scripting

Hi guys,
here https://www.unix.com/shell-programmin...-awk-perl.html I found awk script converting

Code:

awk '{
    OFS = ";"
    if (t) {
       if (l != $1)
          t = t OFS $1
    } else t = OFS $1
    x[$1] = x[$1] ? x[$1] OFS $NF : $NF
    l = $1
} END {
    print t
    for (i in x) print i, x[i]
}'

a ; a ; 1
a ; b ; 0,8
a ; c ; 0,5
b ; a ; 0,8
b ; b ; 1
b ; c ; 0,2
c ; a ; 0,5
c ; b ; 0,2
c ; c ; 1

into


;a;b;c
a;1;0,8;0,5
b;0,8;1;0,2
c;0,5;0,2;1

The problem is that in my input file looks like this

a ; b ; 0,8
a ; c ; 0,5
b ; a ; 0,8
b ; c ; 0,2
c ; a ; 0,5
c ; b ; 0,2

and I would like to my output file to look like this:

;a;b;c
a;--;0,8;0,5
b;0,8;--;0,2
c;0,5;0,2;--

Can you help me converting the script so that it will do the work?
Thanks in advance for your help!

Try this:

Code:

awk -F " ; " '{
    t[$1]
    x[$1,$2] = $NF
} END {
    for(h in t) printf ";%s", h;
    printf "\n"
    for(v in t) {
       printf "%s", v
       for(h in t)
          if((h SUBSEP v) in x) printf ";%s", x[h,v]
          else printf ";--"
       printf "\n"
    }
}' infile

Works great, thanks!