Shell Programming and Scripting

I have two files

File 1 in reading directory is of following format

File 2 in directory contains
File2 contains

I need to read file 2 first for positons and print out the corresponding value in fourth column from opened file, in directory, in horizontal manner. If no match for that postion, it is printed as "-". The output for above should be

Code:

     1 2 3 4 5 6 7
Read T - C - T - G
Read - - - - G C A

I need to do that for all the files and print in above format in another row. so output will be only one file with number of rows equals no of files. Can i do this in perl easily?

file is the index (file2 in your example with "1 2 3 4 5 6 7").

Code:

awk '
function print_tab()
{
  for (k=1;k<=j;k++) {
    i=ind[k]
    printf "%-4s",tab[i]
    tab[i]="-"
  }
  printf "\n"
}

FNR == NR {j++ ; ind[j]=$1 ; tab[$1]=$1 ; next}
FNR == 1 && NR !=1 {print_tab()}
$2 in tab {tab[$2]=$4}
END {print_tab()}
' file file1 file2

So there are two arrays:
- ind : is a buffer of the index file. ind[i] is the content of the i line. (in your exemple ind[1]=1…)
- tab : is the letter of the number of the second field. first line : tab[1]=1, second line tab[1]=T, third line tab[1]=-

Code:

FNR == NR {j++ ; ind[j]=$1 ; tab[$1]=$1 ; next}

when awk read the first file (so the index file with 1 2 3 4 5 6 7) we fill in arrays. Please note that "j" will be the number of line of the first file after the reading (7 in the example).

Code:

FNR == 1 && NR !=1 {print_tab()}

when awk read the first line of others file print the line

Code:

$2 in tab {tab[$2]=$4}

when the second file is in the index of tab we fill in with the value



PRINT TAB :

Code:

for (k=1;k<=j;k++) {

k between 1 and j (number of line in the index file).

Code:

i=ind[k]

so i is now the "k" line of index file.

Code:

printf "%-4s",tab[i]

print the corresponding letter

Code:

tab[i]="-"

refresh array with "-"[/code]