10 More Discussions You Might Find Interesting
1. Shell Programming and Scripting
Hello,
This is really breaking my head. I request you help to solve this problem.
I have a list of files at the source directory (/tmp) as below,
NewTransfer_20131202_APAC.dat
NewTransferFile_20131202_APAC.dat
NewTransfer_20131203_APAC.dat
NewTransferFile_20131203_APAC.dat... (3 Replies)
Discussion started by: sravicha
3 Replies
2. Shell Programming and Scripting
Hey everyone,
I have a bunch of lines with values in field 4 that I am interested in.
If these values are between 1 and 3 I want it to count all these values to all be counted together and then have the computer print out
LOW and the number of lines with those values in between 1 and 3,... (2 Replies)
Discussion started by: VagabondGold
2 Replies
3. Shell Programming and Scripting
Hi,
i have a problem with this script:
for i in $(cat list_ip_switch)
do
if
if ; then
echo "found ip"
else
echo "not found ip"
fi
done
cat list_ip_switch
10.155.249.171
10.155.249.172 (3 Replies)
Discussion started by: elilmal
3 Replies
4. Shell Programming and Scripting
I have a file data_1.out which contains:
1|abc mail|mail subject|mail body
2|def mail|mail subject|def mail body
I am trying to read the variables from data_1.out and use them to print to 2 different files based on the id (first_column)
The problem is I am not able to read the file... (8 Replies)
Discussion started by: sol_nov
8 Replies
5. Shell Programming and Scripting
Dear all, today I'm scratching my head with a simple (I believe) issue.
Working with date is quite simple, so if I Need to add some seconds to current time, I'll use:
date --date='+30 seconds' +"%Y-%m-%d %H:%M:%S"But, how to pass the value to add from a variable? I tried the following without... (2 Replies)
Discussion started by: Lord Spectre
2 Replies
6. Shell Programming and Scripting
Experts,
I have a bash shell script that generates 2 variables that have the current minute and a minute from a log file. Can someone please show me the best way to test if the minutes stray by 5. So basically if:
This is ok:
Last Fitting Min
=============
02
Current Minute
=============... (2 Replies)
Discussion started by: jaysunn
2 Replies
7. UNIX for Dummies Questions & Answers
hi,
want to create script that takes name of directory and all files and will copy each file to new directory.
then fix errors like files do not exist or no permission to create new directory...
these what I have so far...
#!/bin/sh
dir=~/Documents/Scripts/Copy
for i in $(pwd) $(ls)... (23 Replies)
Discussion started by: me.
23 Replies
8. Shell Programming and Scripting
Hello guys,
First of all, thanks for taking the time to read my post.
So, here I have a file from my honeypot which record IP addresses and web pages visited. I would like to manipulate it in order to create Snort signatures and ACLs.
But I am having troubles to extract the src IP address and... (6 Replies)
Discussion started by: Benou
6 Replies
9. Shell Programming and Scripting
I'm trying to understand if it's possible to create a set of variables that are numbered based on another variable (using eval) in a loop, and then call on it before the loop ends.
As an example I've written a script called question (The fist command is to show what is the contents of the... (2 Replies)
Discussion started by: DeCoTwc
2 Replies
10. Shell Programming and Scripting
Sorry for such a dreadful title, but I'm not sure how to be more descriptive. I'm hoping some of the more gurutastic out there can take a look at a solution I came up with to a problem, and advice if there are better ways to have gone about it.
To make a long story short around 20K pieces of... (2 Replies)
Discussion started by: DeCoTwc
2 Replies
Gtk2::GladeXML::Simple(3pm) User Contributed Perl Documentation Gtk2::GladeXML::Simple(3pm)
NAME
Gtk2::GladeXML::Simple - A clean object-oriented interface to Gtk2::GladeXML
SYNOPSIS
package MyApp;
use base qw( Gtk2::GladeXML::Simple );
sub new {
my $class = shift;
my $self = $class->SUPER::new( $gladefile );
return $self;
}
...
# Signal handlers are methods of your class
sub on_button_clicked {
my $self = shift;
# You have access to your widgets directly
# or using $self->get_widget( widget_name )
my $button = $self->{button1};
}
DESCRIPTION
Gtk2::GladeXML::Simple is a module that provides a clean and easy interface for Gnome/Gtk2 and Glade applications using an object-oriented
syntax. You just make Gtk2::GladeXML::Simple your application's base class, have your "new" call "SUPER::new", and the module will do the
tedious and dirty work for you.
Gtk2::GladeXML::Simple offers:
o Signal handler callbacks as methods of your class.
sub on_button1_clicked {
my $self = shift; # $self always received as first parameter
...
# do anything you want in a OO fashioned way
}
o Autoconnection of signal handlers.
o Autocalling of creation functions for custom widgets.
o Access to the widgets as instance attributes.
my $btn = $self->{button1}; # fetch widgets as instance attributes by their names
my $window = $self->{main_window};
my $custom = $self->{custom_widget};
METHODS
This class provides the following public methods:
new( $gladefile [, $root, $domain ] );
This method creates a new object of your subclass of Gtk2::GladeXML::Simple. The $gladefile parameter is the name of the file created
by the Glade Visual Editor. The $root is an optional parameter that tells "libglade" the name of the widget to start building from.
The optional $domain parameter that specifies the translation domain for the glade xml file ( undef by default ).
glade_object
This method returns the Gtk2::GladeXML object in play.
get_widget( $widget_name )
Returns the widget with given name. Same as calling $self->{$widget_name}.
get_widgets
Returns a list with all the widgets in the glade file.
run Call this method in order to run your application. If you need another event loop rather than the Gtk one, override run in your class
with your event loop (for example the GStreamer event loop).
EXTENDED EXAMPLE
This example shows the usage of the module by creating a small Yahoo search engine using WWW::Search::Yahoo.
package YahooApp;
use strict;
use warnings;
use Gtk2 '-init';
use Gtk2::Html2; #not part of the Gtk2 core widgets
use Gtk2::GladeXML::Simple;
use WWW::Search;
use base qw( Gtk2::GladeXML::Simple );
my $header =<<HEADER;
<html>
<meta HTTP-EQUIV="content-type" CONTENT="text/html; charset=UTF-8">
<header><title>Yahoo Gtk2 App</title>
<style type="text/css">
.title {font-family: Georgia; color: blue; font-size: 13px}
.description {padding-left: 3px; font-family: Georgia; font-size:10px}
.url {padding-left: 3px; font-family: Georgia; font-size:10px; color: green}
</style>
</head>
<body>
<h2 style="font-family: Georgia, Arial; font-weight: bold">
Found:
</h2>
HEADER
my $footer =<<FOOTER;
</body>
</html>
FOOTER
sub new {
my $class = shift;
#Calling our super class constructor
my $self = $class->SUPER::new( 'yahoo.glade' );
#Initialize the search engine
$self->{_yahoo} = WWW::Search->new( 'Yahoo' );
return $self;
}
sub do_search {
my $self = shift;
$self->{_yahoo}->native_query( shift );
my $buf = $header;
for( 1..10 ) {
my $rv = $self->{_yahoo}->next_result || last;
$buf .= qq{<p><div class="title">} . $rv->title;
$buf .= qq{</div><br /><div class="description">} . $rv->description;
$buf .= qq{</div><br /><div class="url">} . $rv->url . q{</div></p><br />};
}
$buf .= $footer;
$self->{buf} = $buf;
}
### Signal handlers, now they're methods of the class ###
sub on_Clear_clicked {
my $self = shift;
my $html = $self->{custom1}; #fetch widgets by their names
$html->{document}->clear;
my $statusbar = $self->{statusbar1}; #another widget
$statusbar->pop( $statusbar->get_context_id( "Yahoo" ) );
}
sub on_Search_clicked {
my $self = shift;
my $text = $self->{text_entry}->get_text;
return unless $text ne '';
my $statusbar = $self->{statusbar1};
$statusbar->push( $statusbar->get_context_id( "Yahoo" ), "Searching for: $text" );
$self->do_search( $text );
my $html = $self->{custom1};
$html->{document}->clear;
$html->{document}->open_stream( "text/html" );
$html->{document}->write_stream( $self->{buf} );
$html->{document}->close_stream;
}
### Creation function for the custom widget, method of the class as well ###
sub create_htmlview {
my $self = shift;
my $view = Gtk2::Html2::View->new;
my $document = Gtk2::Html2::Document->new;
$view->set_document( $document );
$view->{document} = $document;
$view->show_all;
return $view;
}
sub gtk_main_quit { Gtk2->main_quit }
1;
package main;
YahooApp->new->run; #Go!
1;
The yahoo.glade file needed for this example is in the examples directory, along with other example programs.
UTILITIES
Rapid Application Development with gpsketcher
The Gtk2::GladeXML::Simple distribution includes gpsketcher, a program that generates Perl code stubs from glade XML files. The code stubs
include the basic framework for Gtk2::GladeXML::Simple interaction, method signatures, and everything that describes the application
itself. Developers must fill in the code stubs to add the correct functionality to the application.
SEE ALSO
Gtk2::GladeXML, Gtk2, gpsketcher
The Libglade Reference Manual at <http://developer.gnome.org/doc/API/2.0/libglade/>
The gtk2 API Reference at <http://developer.gnome.org/doc/API/2.0/gtk/index.html>
TODO
Tests.
More examples?
Add Gtk2::GladeXML::Simple::new_from_buffer()?
Support to I18N ( bindtextdomain )
AUTHOR
Marco Antonio Manzo <marcoam@perl.org.mx>
Special thanks in no order to Scott Arrington "muppet" <scott at asofyet dot org> who provided lots of great ideas to improve this module.
Sandino "tigrux" Flores <tigrux at ximian dot com> who is the author of SimpleGladeApp and the main source of this module's core idea.
Sean M. Burke <sburke at cpan dot org> and Rocco Caputo <rcaputo at cpan dot org> for constantly helping me with ideas and cleaning my POD.
COPYRIGHT AND LICENSE
Copyright (C) 2005 by Marco Antonio Manzo
This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself, either Perl version 5.8.6 or,
at your option, any later version of Perl 5 you may have available.
perl v5.10.1 2005-07-23 Gtk2::GladeXML::Simple(3pm)