Shell Programming and Scripting

Attribute                        Value
------------------------- ----------------------------
State                            Full Access
Active sessions                  0
Total capacity                   7.8 TB
Capacity used                    3.2 TB
Server utilization               40.8%
Bytes protected                  0 bytes
Bytes protected quota            Not configured
License expiration               Never
Time since Server initialization 203 days 21h:42m
Last checkpoint                  2012-05-02 12:45:10 PDT
Last validated checkpoint        2012-05-02 11:04:48 PDT

Total Capacity  Utilization  Used Capacity

7.8 TB               40.2 %      3.2 TB

Total Capacity ,Utilization ,Used Capacity,,,

# Field separator is two or more spaces
BEGIN { FS="   *";      OFS=",";        ORS="\r\n"      }
# Ignore first two lines, then store in array
NR>2 { sub(/ *$/, ""); A[$1]=$2; }

END {
        print "Total Capacity", "Utilization", "Used Capacity";
        print A["Total capacity"], A["Server utilization"], A["Capacity used"];
}

# The 'begin' section is run before any files are opened by awk.
# Use it to set up these variables.
BEGIN { FS="   *";      OFS=",";        ORS="\r\n"      }

# NR is the number of records.
# The code block here will only get run when NR is greater than two.
# Ergo, it ignores the first two lines.
NR>2 {
        # Get rid of some spaces at the end of the line
        sub(/ *$/, "");
        # Store like A["Total capacity"]=7.8 TB
        A[$1]=$2; }

# This code block only gets run when awk runs out of files.
END {
        # Print our titles
        print "Total Capacity", "Utilization", "Used Capacity";
        # Print the various things we stored in the array before
        print A["Total capacity"], A["Server utilization"], A["Capacity used"];
}