Shell Programming and Scripting

awk '
    FILENAME != lfn { idx++; }
    {
        lfn = FILENAME;

        v = $NF;
        $NF = "";
        data[$0, idx] = v;
        seen[$0] = 1;
    }

    END {
        for( x in seen )
        {
            printf( "%s", x );
            for( i = 1; i <= idx; i++ )
                printf( "\t%s", data[x,i] ? data[x,i] : "Nothing" );
            printf( "\n" );
        }
    }
'  month1 month2 month3 month4

awk '
    FILENAME != lfn { idx++; }      # if filename for this rec is different than last, bump index
    {
        lfn = FILENAME;             # save last filename seen for check above

        v = $NF;                    # save value from last token on record
        $NF = "";                   # delete the last token from the input record
        data[$0, idx] = v;          # use the current record (in this case the name) and the index to save value
                                    # this preserves order and allows us to detect missing values
        seen[$0] = 1;               # keep a list of user strings that we encountered
    }

    END {
        for( x in seen )            # for each user string we saw
        {
            printf( "%s", x );      # print the name
            for( i = 1; i <= idx; i++ )     # for each index (input file, in same order given on command
                printf( "\t%s", data[x,i] ? data[x,i] : "Nothing" );    # print the value saved, or "nothing" if no value in file
            printf( "\n" );         # final termination of output record for this id string.
        }
    }

'  month1 month2 month3 month4