Shell Programming and Scripting

I was reading about different methods of awk field ranges. Does the second method have any advantage? Its quite a bit longer so I am wondering what the advantage is.

Code:

awk '{for(i=5;i<=9;i++)printf "%s ",$i;print ""}' filename

http://unix.ittoolbox.com/groups/tec...ranges-1686908

Code:

awk -v f=2 -v t=4 '{ for (i=f; i<=t;i++) printf("%s%s", $i,(i==t) ? "\n" : OFS) }' details.txt

UNIX BASH scripting: Print range of columns using awk - exclude range

There is no advantage, it is just another way. Choose whichever method you like best:

Code:

awk '{for(i=m;i<=n;i++)printf "%s",$i (i==n?RS:OFS)}' m=2 n=4 infile

Code:

awk '{for(i=m;i<=n;i++){ORS=(i==n)?RS:OFS;print $i}}' m=2 n=4 infile

Code:

awk '{for(i=m;i<=n;i++)printf "%s" OFS,$i; print x}' m=2 n=4 infile

Code:

awk '{s=x;for(i=m;i<=n;i++)s=s (s?OFS:x) $i;print s}' m=2 n=4 infile

Code:

awk '{s=$m;for(i=m+1;i<=n;i++)s=s OFS $i;print s}' m=2 n=4 infile

There are two "disadvantages" with the first version in my opinion:

1. With the first version there will be a space at the end of the lines (with non default OFS this will be more evident).
This might be or might not be an issue depending on the requirement.

2. The first version in its actual form does not allow for the field range, the field separator and the output record separator ORS
to be passed as parameters (which adds flexibility).

I always use a version similar to the second one (I use ORS instead of \n for flexibility).