Shell Programming and Scripting

fileA
xxxxxx   567890  456789
kjlajl   3456789 489080
xxxxxx   klkio   467830

Output expected:
xxxxx "array executed"(from file after reading array one by one in for loop)
xxxxx  567890  456789
xxxxx   klkio   467830
kjlajl "array execcuted"(again from file after reading array)
kjlajl  3456789 489080

code I have tried:
$ nawk -F, 'NR==FNR{arr1[i++]=$1}
 {
for(i in arr1)
 {if($0~arr1[i]) print arr1[i]"executed""\n"$0}}' fileA

# if order is important
awk '
    {
        if( !seen[$1]++ )               # track order that field 1 was observed
            order[oidx++] = $1;

        map[$1,idx[$1]++]= $0;          # save each line based on the first field
    }
    END {
        for( o = 0; o < oidx; o++ )      # for each field 1 in the order seen
        {
            printf( "executed: %s\n", order[o] );
            for( m = 0; m < idx[order[o]]; m++ )   # for each line associated with field 1 value
                printf( "%s\n", map[order[o],m] );

        }
    }
' testfile

# if output order isn't important
awk '
    {
        map[$1,idx[$1]++]= $0;          # save each line based on the first field
    }
    END {
        for( i in idx )              # for each field 1 seen (any order)
        {
           printf( "executed: %s\n", i );
           for( m = 0; m < idx[i]; m++ )   # for each line associated with this field 1
               printf( "%s\n", map[i,m] );
        }
    }
' testfile

sort infile |awk '!a[$1]++ {print "executed: " $1}1'