Shell Programming and Scripting

group1	user1
	user2
	user3
group2	user4
	user5
	user1
group3	user6
	user7
	user8

group1
group2

BEGIN
{
  i=0;                                  # declaring variable
}

{
  if (NF==2){currgrp=$1;}               # check whether awk actually processing 2 column record, if yes save the group name
  else
     {
      if ($1~/uname/)                   # else if awk is processing 1 column record and is found user name, save the group name to array and increment i
       {
         netgroups[i]=currgrp;
         i++;
       }
     }
}

END                                     # at the end of processing whole file print the array (all saved groups)
{
  for(j=0;j<i;j++)
  {
    print netgroups[i];
  }
}

awk -v uname="user1" -f awkscript.awk group_file

$ cat Test1
awk '
 $2 { G = $1 }
 $NF == U && ! _[G]++ { print G }
' U="$1" file1

$ cat file1
group1	user1
	user2
	user3
group2	user4
	user5
	user1
group3	user6
	user7
	user8

$ ./Test1 user1
group1
group2

awk -v uname="user1" 'END {
  while (++j <= i) print netgroups[j]
  }
NF == 2 { currgrp = $1 }
$0 ~ uname { netgroups[++i] = currgrp }
' group_file

awk  'NF == 2 { g = $1 }
$NF ~ u && $0 = g x
' u="user1" group_file

$ u=user1
$ sed -n '/^group/h; /'"$u"'/{g;s/[[:blank:]].*$//;p;}' file
group1
group2

BEGIN {                          # do not put BEGIN on a line by itself   
  i = 0                          # no need to initialize the counter,
                                 # awk does this automatically
  }                                 
{
  if (NF == 2) {
    currgrp = $1
    if ($2 ~ uname) {
      netgroups[i] = currgrp     # you shoud check if the username matches 
      i ++                       # when NF == 2 too
      }
    }        
  else
     {
      if ($1 ~ uname) {           # /uname/ matches litteral "uname"
         netgroups[i] = currgrp
         i ++
       }
     }
}

END {                             # do not put END on a line by itself
  for(j = 0; j < i;j ++)             
  {
    print netgroups[j]            # j not i!
  }
}

$ cat beginend.awk 
BEGIN {
    print "begin"
}

END {
    print "end"
}

$ echo | awk -f beginend.awk 
begin
end