Shell Programming and Scripting

Gurus,

I have one file which is having multiple columns and also this file is not always contain the exact columns; sometimes it contains 5 columns or 12 columns. Now, I need to find the difference from that particular file. Here is the sample file:

Code:

param1 | 10 | 20 | 30 |
param2 | 10 | 10 | 10 |
param3 | AB | AB | BC|
param4 | AB | BC | AB |
param5 | AA | AA | AA|

Now, the output print the difference only:

Code:

param1 | 10 | 20 | 30 |
param3 | AB | AB | BC |
param4 | AB | BC | AB |

I tried doing this in awk; but because the number of file columns are not same everytime. so, please help me on this either with awk, perl or any unix solution.

Thanks

$ cat data

Code:

param1 | 10 | 20 | 30 |
param2 | 10 | 10 | 10 |
param3 | AB | AB | BC|
param4 | AB | BC | AB |
param5 | AA | AA | AA|

$ awk -F' *\\| *' '{NF--; for(i=2;i<NF;i++) if ($i!=$(i+1)) {print; next}}' data
param1 | 10 | 20 | 30 |
param3 | AB | AB | BC|
param4 | AB | BC | AB |

Thanks Alister.

You're very welcome, buzzusa.

The following should give the same results as my first solution (after I posted, I decided to try for something more succinct):

Code:

awk -F' *\\| *' '{for(i=3; i<=NF-1 && $2==$i; i++);} i<NF' data

Take care,
alister

Not understand "i<NF", can you explain?

Hello, rdcwayx:

The empty for loop compares the relevant fields ($2 through $(NF-1) ... NF is always empty) and stops when either a difference has been found or we've run out of fields to compare. If we ran out of fields to compare, i equals NF and i<NF will be false. In this case, nothing happens, as desired. If instead the for loop terminates due to a difference between $2 and some relevant field, $i, then i<NF will be true and the default action of print $0 will be executed.

Hope that clears it up.

Take care,
alister