excel::writer::xlsx::chart::pie(3pm) [debian man page]

Excel::Writer::XLSX::Chart::Pie(3pm)			User Contributed Perl Documentation		      Excel::Writer::XLSX::Chart::Pie(3pm)

NAME

       Pie - A class for writing Excel Pie charts.

SYNOPSIS

       To create a simple Excel file with a Pie chart using Excel::Writer::XLSX:

	   #!/usr/bin/perl

	   use strict;
	   use warnings;
	   use Excel::Writer::XLSX;

	   my $workbook  = Excel::Writer::XLSX->new( 'chart.xlsx' );
	   my $worksheet = $workbook->add_worksheet();

	   my $chart	 = $workbook->add_chart( type => 'pie' );

	   # Configure the chart.
	   $chart->add_series(
	       categories => '=Sheet1!$A$2:$A$7',
	       values	  => '=Sheet1!$B$2:$B$7',
	   );

	   # Add the worksheet data the chart refers to.
	   my $data = [
	       [ 'Category', 2, 3, 4, 5, 6, 7 ],
	       [ 'Value',    1, 4, 5, 2, 1, 5 ],
	   ];

	   $worksheet->write( 'A1', $data );

	   __END__

DESCRIPTION

       This module implements Pie charts for Excel::Writer::XLSX. The chart object is created via the Workbook "add_chart()" method:

	   my $chart = $workbook->add_chart( type => 'pie' );

       Once the object is created it can be configured via the following methods that are common to all chart classes:

	   $chart->add_series();
	   $chart->set_title();

       These methods are explained in detail in Excel::Writer::XLSX::Chart. Class specific methods or settings, if any, are explained below.

Pie Chart Methods
       There aren't currently any pie chart specific methods. See the TODO section of Excel::Writer::XLSX::Chart.

       A Pie chart doesn't have an X or Y axis so the following common chart methods are ignored.

	   $chart->set_x_axis();
	   $chart->set_y_axis();

EXAMPLE

       Here is a complete example that demonstrates most of the available features when creating a chart.

	   #!/usr/bin/perl

	   use strict;
	   use warnings;
	   use Excel::Writer::XLSX;

	   my $workbook  = Excel::Writer::XLSX->new( 'chart_pie.xlsx' );
	   my $worksheet = $workbook->add_worksheet();
	   my $bold	 = $workbook->add_format( bold => 1 );

	   # Add the worksheet data that the charts will refer to.
	   my $headings = [ 'Category', 'Values' ];
	   my $data = [
	       [ 'Apple', 'Cherry', 'Pecan' ],
	       [ 60,	   30,	     10     ],
	   ];

	   $worksheet->write( 'A1', $headings, $bold );
	   $worksheet->write( 'A2', $data );

	   # Create a new chart object. In this case an embedded chart.
	   my $chart = $workbook->add_chart( type => 'pie', embedded => 1 );

	   # Configure the series. Note the use of the array ref to define ranges:
	   # [ $sheetname, $row_start, $row_end, $col_start, $col_end ].
	   $chart->add_series(
	       name	  => 'Pie sales data',
	       categories => [ 'Sheet1', 1, 3, 0, 0 ],
	       values	  => [ 'Sheet1', 1, 3, 1, 1 ],
	   );

	   # Add a title.
	   $chart->set_title( name => 'Popular Pie Types' );

	   # Set an Excel chart style. Colors with white outline and shadow.
	   $chart->set_style( 10 );

	   # Insert the chart into the worksheet (with an offset).
	   $worksheet->insert_chart( 'C2', $chart, 25, 10 );

	   __END__

AUTHOR

       John McNamara jmcnamara@cpan.org

COPYRIGHT

       Copyright MM-MMXII, John McNamara.

       All Rights Reserved. This module is free software. It may be used, redistributed and/or modified under the same terms as Perl itself.

perl v5.10.1							    2012-04-02				      Excel::Writer::XLSX::Chart::Pie(3pm)

Excel::Writer::XLSX::Chart::Stock(3pm)			User Contributed Perl Documentation		    Excel::Writer::XLSX::Chart::Stock(3pm)

NAME

       Stock - A class for writing Excel Stock charts.

SYNOPSIS

       To create a simple Excel file with a Stock chart using Excel::Writer::XLSX:

	   #!/usr/bin/perl -w

	   use strict;
	   use Excel::Writer::XLSX;

	   my $workbook  = Excel::Writer::XLSX->new( 'chart.xlsx' );
	   my $worksheet = $workbook->add_worksheet();

	   my $chart	 = $workbook->add_chart( type => 'stock' );

	   # Add a series for each High-Low-Close.
	   $chart->add_series( categories => '=Sheet1!$A$2:$A$6', values => '=Sheet1!$B$2:$B$6' );
	   $chart->add_series( categories => '=Sheet1!$A$2:$A$6', values => '=Sheet1!$C$2:$C$6' );
	   $chart->add_series( categories => '=Sheet1!$A$2:$A$6', values => '=Sheet1!$D$2:$D$6' );

	   # Add the worksheet data the chart refers to.
	   # ... See the full example below.

	   __END__

DESCRIPTION

       This module implements Stock charts for Excel::Writer::XLSX. The chart object is created via the Workbook "add_chart()" method:

	   my $chart = $workbook->add_chart( type => 'stock' );

       Once the object is created it can be configured via the following methods that are common to all chart classes:

	   $chart->add_series();
	   $chart->set_x_axis();
	   $chart->set_y_axis();
	   $chart->set_title();

       These methods are explained in detail in Excel::Writer::XLSX::Chart. Class specific methods or settings, if any, are explained below.

Stock Chart Methods
       There aren't currently any stock chart specific methods. See the TODO section of Excel::Writer::XLSX::Chart.

       The default Stock chart is an High-Low-Close chart. A series must be added for each of these data sources.

EXAMPLE

       Here is a complete example that demonstrates most of the available features when creating a Stock chart.

	   #!/usr/bin/perl

	   use strict;
	   use warnings;
	   use Excel::Writer::XLSX;
	   use Excel::Writer::XLSX;

	   my $workbook    = Excel::Writer::XLSX->new( 'chart_stock.xlsx' );
	   my $worksheet   = $workbook->add_worksheet();
	   my $bold	   = $workbook->add_format( bold => 1 );
	   my $date_format = $workbook->add_format( num_format => 'dd/mm/yyyy' );
	   my $chart	   = $workbook->add_chart( type => 'stock', embedded => 1 );

	   # Add the worksheet data that the charts will refer to.
	   my $headings = [ 'Date', 'High', 'Low', 'Close' ];
	   my $data = [

	       [ '2007-01-01T', '2007-01-02T', '2007-01-03T', '2007-01-04T', '2007-01-05T' ],
	       [ 27.2,	25.03, 19.05, 20.34, 18.5 ],
	       [ 23.49, 19.55, 15.12, 17.84, 16.34 ],
	       [ 25.45, 23.05, 17.32, 20.45, 17.34 ],

	   ];

	   $worksheet->write( 'A1', $headings, $bold );

	   for my $row ( 0 .. 4 ) {
	       $worksheet->write_date_time( $row+1, 0, $data->[0]->[$row], $date_format );
	       $worksheet->write( $row+1, 1, $data->[1]->[$row] );
	       $worksheet->write( $row+1, 2, $data->[2]->[$row] );
	       $worksheet->write( $row+1, 3, $data->[3]->[$row] );

	   }

	   $worksheet->set_column( 'A:D', 11 );

	   # Add a series for each of the High-Low-Close columns.
	   $chart->add_series(
	       categories => '=Sheet1!$A$2:$A$6',
	       values	  => '=Sheet1!$B$2:$B$6',
	   );

	   $chart->add_series(
	       categories => '=Sheet1!$A$2:$A$6',
	       values	  => '=Sheet1!$C$2:$C$6',
	   );

	   $chart->add_series(
	       categories => '=Sheet1!$A$2:$A$6',
	       values	  => '=Sheet1!$D$2:$D$6',
	   );

	   # Add a chart title and some axis labels.
	   $chart->set_title ( name => 'High-Low-Close', );
	   $chart->set_x_axis( name => 'Date', );
	   $chart->set_y_axis( name => 'Share price', );

	   $worksheet->insert_chart( 'E9', $chart );

	   __END__

AUTHOR

       John McNamara jmcnamara@cpan.org

COPYRIGHT

       Copyright MM-MMXII, John McNamara.

       All Rights Reserved. This module is free software. It may be used, redistributed and/or modified under the same terms as Perl itself.

perl v5.10.1							    2012-04-02				    Excel::Writer::XLSX::Chart::Stock(3pm)