dbix::class::helper::resultset::setoperations(3pm) [debian man page]

DBIx::Class::Helper::ResultSet::SetOperations(3pm)	User Contributed Perl Documentation	DBIx::Class::Helper::ResultSet::SetOperations(3pm)

NAME

       DBIx::Class::Helper::ResultSet::SetOperations - Do set operations with DBIx::Class

VERSION

       version 2.013002

SYNOPSIS

	package MyApp::Schema::ResultSet::Foo;

	__PACKAGE__->load_components(qw{Helper::ResultSet::SetOperations});

	...

	1;

       And then elsewhere, like in a controller:

	my $rs1 = $rs->search({ foo => 'bar' });
	my $rs2 = $rs->search({ baz => 'biff' });
	for ($rs1->union($rs2)->all) { ... }

DESCRIPTION

       This component allows you to use various set operations with your ResultSets.  See "NOTE" in DBIx::Class::Helper::ResultSet for a nice way
       to apply it to your entire schema.

       Component throws exceptions if ResultSets have different ResultClasses or different "Columns Specs."

       The basic idea here is that in SQL if you use a set operation they must be selecting the same columns names, so that the results will all
       match.  The deal with the ResultClasses is that DBIC needs to inflate the results the same for the entire ResultSet, so if one were to try
       to apply something like a union in a table with the same column name but different classes DBIC wouldn't be doing what you would expect.

       A nice way to use this is with DBIx::Class::ResultClass::HashRefInflator.

       You might have something like the following sketch autocompletion code:

	my $rs1 = $schema->resultset('Album')->search({
	   name => { -like => "$input%" }
	}, {
	  columns => [qw( id name ), {
	     tablename => ['?', [{} => 'album']],
	  }],
	});

	my $rs2 = $schema->resultset('Artist')->search({
	   name => { -like => "$input%" }
	}, {
	  columns => [qw( id name ), {
	     tablename => ['?', [{} => 'artist']],
	  }],
	});

	my $rs3 = $schema->resultset('Song')->search({
	   name => { -like => "$input%" }
	}, {
	  columns => [qw( id name ), {
	     tablename => ['?', [{} => 'song']],
	  }],
	});

	$_->result_class('DBIx::Class::ResultClass::HashRefInflator')
	  for ($rs1, $rs2, $rs3);

	my $data = [$rs1->union([$rs2, $rs3])->all];

METHODS

   union
   union_all
   intersect
   intersect_all
   except
   except_all
       All of these methods take a single ResultSet or an ArrayRef of ResultSets as the parameter only parameter.

       On Oracle "except" will issue a "MINUS" operation.

AUTHOR

       Arthur Axel "fREW" Schmidt <frioux+cpan@gmail.com>

COPYRIGHT AND LICENSE

       This software is copyright (c) 2012 by Arthur Axel "fREW" Schmidt.

       This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

perl v5.14.2							    2012-06-18			DBIx::Class::Helper::ResultSet::SetOperations(3pm)

DBIx::Class::Helper::ResultSet::SearchOr(3pm)		User Contributed Perl Documentation	     DBIx::Class::Helper::ResultSet::SearchOr(3pm)

NAME

       DBIx::Class::Helper::ResultSet::SearchOr - Combine ResultSet searches with OR's

VERSION

       version 2.013002

SYNOPSIS

	package MyApp::Schema::ResultSet::Tests;

	use base 'DBIx::Class::ResultSet';

	__PACKAGE__->load_components(qw(Helper::ResultSet::IgnoreWantarray Helper::ResultSet::SearchOr));

	sub failed {
	  my $self = shift;

	  my $me = $self->current_source_alias;

	  $self->search({ "$me.passed" => '0' });
	}

	sub untested {
	  my $self = shift;

	  my $me = $self->current_source_alias;

	  $self->search({ "$me.passed" => undef });
	}

	sub not_passed {
	  my $self = shift;

	  my $me = $self->current_source_alias;

	  $self->search_or([$self->failed, $self->untested]);
	}

	1;

DESCRIPTION

       I would argue that the most important feature of DBIx::Class is the fact that you can "chain" ResultSet searches.  Unfortunately this can
       cause problems when you need to reuse multiple ResultSet methods as... well as or's.  In the past I got around this by doing:

	$rs->foo->union([ $rs->bar]);

       While this works, it can generate some hairy SQL pretty fast.  This Helper is supposed to basically be a lightweight union.  Note that it
       therefor has a number of "LIMITATIONS".	The thing that makes this module special is that the ResultSet that is doing the "search_or" ing
       still limits everything correctly.  To be clear, the following only returns $user's friends that match either of the following criteria:

	my $friend_rs = $schema->resultset('Friend');
	my @internet_friends = $user->friends->search_or([
	  $friend_rs->on_facebook,
	  $friend_rs->on_twitter,
	])->all;

       With a union, you'd have to implement it like this:

	$user->friends->on_facebook->union([ $user->friends->on_twitter ]);

       The union will work, but it will generate more complex SQL that may have lower performance on your database.

       See "NOTE" in DBIx::Class::Helper::ResultSet for a nice way to apply it to your entire schema.

METHODS

   search_or
	my $new_rs = $rs->search_or([ $rs->foo, $rs->bar ]);

       "search_or" takes a single arrayref of ResultSets.  The ResultSets must point to the same source or you will get an error message.
       Additionally, no check is made to ensure that more than one ResultSet is in the ArrayRef, but only passing one ResultSet would not make any
       sense.

LIMITATIONS

       Because this module us basically an expression union and not a true union, "JOIN"'s won't Just Work.  If you have a ResultSet method that
       uses a "JOIN" and you want to "OR" it with another method, you'll need to do something like this:

	my @authors = $authors->search(undef, { join => 'books' })->search_or([
	   $authors->wrote_good_books,
	   $authors->wrote_bestselling_books,
	])->all;

       Furthermore, if you want to "OR" two methods that "JOIN" in the same relationship via alternate paths you must use union.

AUTHOR

       Arthur Axel "fREW" Schmidt <frioux+cpan@gmail.com>

COPYRIGHT AND LICENSE

       This software is copyright (c) 2012 by Arthur Axel "fREW" Schmidt.

       This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.

perl v5.14.2							    2012-06-18			     DBIx::Class::Helper::ResultSet::SearchOr(3pm)