usual(3itk) [debian man page]

usual(3itk)							     [incr Tk]							       usual(3itk)

NAME

       usual - access default option-handling commands
	    for a mega-widget component

SYNOPSIS

       usual ?tag? ?commands?

DESCRIPTION

       The  usual  command  is	used outside of an [incr Tcl] class definition to define the usual set of option-handling commands for a component
       widget.	Option-handling commands are used when a component is registered with the Archetype base class via the "itk_component add" method.
       They  specify  how  the component's configuration options should be integrated into the composite option list for the mega-widget.  Options
       can be kept, renamed, or ignored, as described in the Archetype man page.

       It is tedious to include the same declarations again and again whenever components are added.  The usual command  allows  a  standard  code
       fragment to be registered for each widget class, which is used by default to handle the options.  All of the standard Tk widgets have usual
       declarations defined in the [incr Tk] library.  Similar usual declarations should be created whenever a new mega-widget class is conceived.
       Only the most-generic options should be included in the usual declaration.

       The  tag  name  is  usually the name of a widget class, which starts with a capital letter; however, any string registered here can be used
       later with the usual command described on the Archetype man page.

       If the commands argument is specified, it is associated with the tag string, and can be accessed later via itk_component add.

       If only the tag argument is specified, this command looks for an existing tag name and returns the commands associated with it.	 If  there
       are no commands associated with tag, this command returns the null string.

       If no arguments are specified, this command returns a list of all tag names previously registered.

EXAMPLE

       Following is the usual declaration for the standard Tk button widget: itk::usual Button {
	   keep -background -cursor -foreground -font
	   keep -activebackground -activeforeground -disabledforeground
	   keep -highlightcolor -highlightthickness
	   rename  -highlightbackground -background background Background } Only the options that would be common to all buttons in a single mega-
       widget are kept or renamed.  Options like "-text" that would be unique to a particular button are ignored.

KEYWORDS

       itk, Archetype, component, mega-widget

itk									3.0							       usual(3itk)

Widget(n)							     [incr Tk]								 Widget(n)

__________________________________________________________________________________________________________________________________________________

NAME

       Widget - base class for mega-widgets within a frame

INHERITANCE

       itk::Archetype <- itk::Widget

STANDARD OPTIONS

       background      cursor

       See the "options" manual entry for details on the standard options.
_________________________________________________________________

DESCRIPTION

       The Widget class inherits everything from the Archetype class, and adds a Tk frame called the "hull" component to represent the body of the
       mega-widget.  The window class name for the hull is set to the most-specific class  name  for  the  mega-widget.   The  protected  variable
       itk_interior contains the window path name for the "hull" component.  Derived classes specialize this widget by packing other widget compo-
       nents into the hull.

       Since the hull for the Widget class is implemented with a Tk frame, mega-widgets in the Widget class can be packed into	other  frames  and
       toplevels.

COMPONENTS

       Name:	       hull
       Class:	       Frame

	      The  "hull"  component acts as the body for the entire mega-widget.  Other components are packed into the hull to further specialize
	      the widget.

EXAMPLE

       The following example implements a simple TextDisplay mega-widget.  It creates a read-only display of text with a text widget and a scroll-
       bar.
	      option add *TextDisplay.wrap none widgetDefault
	      option add *TextDisplay.textBackground ivory widgetDefault
	      option add *TextDisplay.width 40 widgetDefault
	      option add *TextDisplay.height 10 widgetDefault

	      itcl::class TextDisplay {
		  inherit itk::Widget

		  constructor {args} {
		      itk_component add text {
			  text $itk_interior.info -state disabled		  -yscrollcommand [code $itk_interior.sbar set]
		      } {
			  usual
			  keep -tabs -wrap -width -height
			  rename -background -textbackground textBackground Background
		      }
		      pack $itk_component(text) -side left -expand yes -fill both

		      itk_component add scrollbar {
			  scrollbar $itk_interior.sbar		       -command [code $itk_interior.info yview]
		      }
		      pack $itk_component(scrollbar) -side right -fill y

		      eval itk_initialize $args
		  }

		  public method display {info}
		  public method append {info}
	      }

	      itcl::body TextDisplay::display {info} {
		  $itk_component(text) configure -state normal
		  $itk_component(text) delete 1.0 end
		  $itk_component(text) insert 1.0 $info
		  $itk_component(text) configure -state disabled
	      }

	      itcl::body TextDisplay::append {info} {
		  $itk_component(text) configure -state normal
		  $itk_component(text) insert end $info
		  $itk_component(text) configure -state disabled
	      }

	      itk::usual TextDisplay {
		  keep -background -cursor -foreground -font
		  keep -activebackground -activerelief
		  keep -highlightcolor -highlightthickness
		  keep -insertbackground -insertborderwidth -insertwidth
		  keep -insertontime -insertofftime
		  keep -selectbackground -selectborderwidth -selectforeground
		  keep -textbackground -troughcolor
	      }

	      #
	      # EXAMPLE:  Display the /etc/passwd file
	      #
	      TextDisplay .file -background red
	      pack .file

	      .file display [exec cat /etc/passwd]

KEYWORDS

       itk, Archetype, Widget, mega-widget

itk									3.0								 Widget(n)