Homework & Coursework Questions

  BEGIN{print "Lazy Acres, Inc"
      print "2009 Sales associates Ranking"
      print "Name        Position        Sales amount"
      print "========================================"
      FS=":"
      }

NF==3 {cost[$1]=$3}


NF==4 && $3 ~ /2009/ {tot = $2 * cost[$1]
                      emplId[$4] +=tot}

NF==5 {  emplId2[$1]
         first[$2]
         last[$3]
         position[$5]

      }

$ awk --version | sed '1q'
GNU Awk 3.1.8
$ cat report
BEGIN {
    ## Field separator.
    FS=":";

    ## Header.
    printf("%s\n", "Lazy Acres, Inc.");
    printf("%s\n", "2009 Sales Associates Ranking");
    printf("%-30s %-20s %20s\n", "Name", "Position", "Sales amount");
    for (i = 0; i < 72; i++) {
    printf("%c", "=");
    }
    print;
}

## Associates lines.
## $1 -> Associate ID.
## $2 -> First name.
## $3 -> Position.
NF == 3 {    
    assoc[$1] = $2 ":" $3;
}

## Product lines.
## $1 -> Product ID.
## $4 -> Price.
NF == 4 {
    product[$1] = $4;
}

## Sales lines.
## $2 -> Product ID.
## $3 -> Quantity.
## $4 -> Date.
NF == 5 && $4 ~ /2009/ {
    if ($2 in product) { sales[assoc[$NF]] += $3 * product[$2]; }
}

END {
    ## Sorted associates names.
    asorti(sales, salesSortedI);
    ## Reverse sorted sales (numeric numbers from smallest to biggest).
    asort(sales, salesSortedD);

    j = 0;
    for (i = length(sales); i > 0; i--) {
    j++;
    match(salesSortedI[j], /(.*):(.*)/, a);
    printf("%-30s %-20s %20s\n", a[1], a[2], salesSortedD[i]);
    }
}
$ awk -f report inputfile
Lazy Acres, Inc.
2009 Sales Associates Ranking
Name                           Position                     Sales amount
========================================================================
Buck, Fast                     Stock Boy                         2398.89
Doe, John                      Clerk                             1059.67
Lindon, Rosemary               Producer                           139.76
Miller, Dennis                 Comedian                           134.01
Rush, George                   Salesman                               31
Worker, Susan                  Manager                              8.91

$ tail -n6 report        ## Part of the script supressed.
END {
    for (s in sales) {
    match(s, /(.*):(.*)/, a);
    printf("%-30s\t%-20s\t%20.2f\n", a[1], a[2], sales[s]) | "sort -t\"\t\" -nr -k3"
    } 
}
$ awk -f report inputfile
Lazy Acres, Inc.
2009 Sales Associates Ranking
Name                           Position                     Sales amount
========================================================================
Buck, Fast                      Stock Boy                            2398.89
Rush, George                    Salesman                             1059.67
Worker, Susan                   Manager                               139.76
Doe, John                       Clerk                                 134.01
Lindon, Rosemary                Producer                               31.00
Miller, Dennis                  Comedian                                8.91