Homework & Coursework Questions

Use and complete the template provided. The entire template must be completed. If you don't, your post may be deleted!

1. The problem statement, all variables and given/known data:

I have a simple txt files that looks something like this (The title is a part of the text file)

Code:

Student Grades
---------------
1 Tim Purser 89
2 John Wayne 56
3 Jenn Hawkins 95
4 Harry Potter 75

Here are my questions:

How would I ONLY print the names of students who have a score better than 85?

How would I sort the students based on score: only outputting Student Name and Score?

2. Relevant commands, code, scripts, algorithms:

none

3. The attempts at a solution (include all code and scripts):

I understand how to sort based on grades. But I don't understand how to output based on a condition. I have tried using awk, but I'm having major trouble.

4. Complete Name of School (University), City (State), Country, Name of Professor, and Course Number (Link to Course):

University of Texas
Austin
United States
Erozner
CS108
cs.utexas.edu/~erozner/cs108/


Note: Without school/professor/course information, you will be banned if you post here! You must complete the entire template (not just parts of it).

Code:

code removed by scottn

Moderator's Comments:

In the homework forum it is better to offer advice, education and explanation than simple "one-liner" solutions. Without that, this sub-forum serves no purpose.

Ooops, ok sorry.

To print the student names with score greater than 85:

Code:

awk 'NR > 2 && $NF > 85 {
  print $2, $3
  }' infile

The code means:

- if the current record number (NR) is greater than 2 (skip the header*) and (logical AND - &&) the value of the last field ($NF - NF contains the number of fields, $NF expands to the value of the last field) is greater than 85, print the second and the third field (the student name).

* I'm skipping the header just in case its last field contains a number.

For names that consist of more than two words:

Code:

awk 'NR > 2 && $NF > 85 {
  for (i = 1; ++i < NF;)
    printf "%s", $i (i == NF - 1 ? RS : FS)
  }' infile

In this case you should loop skipping the first and the last field - for (i = 1; ++i < NF;) ...

With GNU awk:

Code:

WHINY_USERS= awk 'END {
  for (S in s)
    print s[S], S
  }
NR > 2 {
  s[$NF] = $2 FS $3
  }' infile

WHINY_USERS is a GNU awk (gawk) magic variable that sorts the array keys. There is a catch of course,
they are strings, so they are sorted asciibetically, not in numeric order (100 is less than 20). You could avoid this by
left-padding the numbers with spaces. (left as an exercise).


For more complicated names:

Code:

WHINY_USERS= awk 'END {
  for (S in s)
    print s[S], S
  }
NR > 2 {
  st = x
  for (i = 1; ++i < NF;)
    st = st ? st FS $i : $i
  s[$NF] = st
  }' infile

Otherwise just print the users and names and then sort them with the external sort program.

Here, as in the previous example, I just added a loop, to print correctly the names consisting of more than two words.


P.S. I'm not explaining the basics of the awk's pattern/action paradigm on purpose, I cannot do it better than the gawk author (just google for Effective gawk Programming).