gawk -v e='%a %d-%m-%Y' '
function regdt(str) {
   c=substr(str, 1, 1)
   ret = "("
   switch(c) {
      case "a":
         ret = ret "[A-Z][a-z]{2}"
      break
      case "d":
         ret = ret "[0-9]{2}"
      break
      case "m":
         ret = ret "[0-9]{2}"
      break
      case "Y":
         ret = ret "[0-9]{4}"
      break
      default:
         print "Unsupported date fmt string: " c
   }
   ctype[capture++] = c
   return ret ")" substr(str, 2)
}
function verify(i,dow,day,month,year) {
   for(v in ctype) {
      value=got[++i]
      switch(ctype[v]) {
         case "a":
             dow = value
         break
         case "d":
             day = value + 0
             if (day < 1 || day > 31)
               return "Illegal dom: " day
         break
         case "m":
             month = value + 0
             if (month < 1 || month > 12)
               return "Illegal month num: " month
         break
         case "Y":
             year = value + 0
             if (year < 1900 || year > 2200)
               return "Illegal year: " year
         break
      }
   }
   if(day == 0 || month == 0 || year == 0)
      return "Must have day, month and year"
   dt=mktime(year " " month " " day " 00 00 00")

   if (day != strftime("%d", dt))
       return "  Illegal day for month" 

   if (dow != "" && strftime("%a", dt) != dow)
       return "  Wrong dow " dow " should be " strftime("%a", dt)

   return ""
}
BEGIN {
   vals=split(e, vl, "%");
   for(i=1; i<=vals; i++)
      if (i==1) expr = vl[i];
      else expr=expr regdt(vl[i])
   print "Regexp is " expr
}
{
    print "String: " $0
    if(match($0, expr, got)) {
        erstr=verify()
        if(erstr == "") print "  Date OK"
        else print "  " erstr
    } else
       print "  Date doesnt match " e " format"
}
' infile

Sat 29-12-2018
Thu 10-02-2019
Fri 30-02-2019
Wed 29-15-2018
Tue 2/2/1900

Regexp is ([A-Z][a-z]{2}) ([0-9]{2})-([0-9]{2})-([0-9]{4})
String: Sat 29-12-2018
  Date OK
String: Thu 10-02-2019
    Wrong dow Thu should be Sun
String: Fri 30-02-2019
    Illegal day for month
String: Wed 29-15-2018
  Illegal month num: 15
String: Tue 2/2/1900
  Date doesnt match %a %d-%m-%Y format