If you want our help, you would do well to provide the information we need to help you (such as was requested two days ago in post #4 in this thread. Since you have chosen to withhold much of the information requested, I will show you code that works with the ksh, awk, and column that are available on macOS High Sierra version 10.13.6. If there are any changes needed to work in your environment, it will be up to you to figure out what changes are needed.

Note that I added the "none given" as data to fill fields that contained no data in an input record because the version of column on my system doesn't seem to recognize two adjacent field separators as delimiters for an empty field.

I have no idea where the Last Name "Peterson" that you said should appear in the last line of your output came from. That name does not appear anywhere in any of the sample input files you have shown us. And, since there were four records in your sample input, I do not understand why your desired sample output only contained three records (not counting the header record).

On my system, when file contains the sample input you provided in post #6, the following code:

Code:

#!/bin/ksh
awk '
BEGIN {	FS = ": |\n"
	OFS = ":"
	RS = ""
	print FNn = "First Name", LNn = "Last Name", An = "Age", Cn = "Country"
}
{	A = C = F = L = "none given"
	for(i = 1; i <= NF; i += 2) {
		if($i == An)
			A = $(i + 1)
		else if($i == Cn)
			C = $(i + 1)
		else if($i == FNn)
			F = $(i + 1)
		else if($i == LNn)
			L = $(i + 1)
	}
	print F, L, A, C
}' file | column -s: -t

produces the output:

Code:

First Name  Last Name   Age         Country
John F      Slater      31          USA
Mark        Watt        35          United Kingdom
Jim         none given  50          Germany
Mike         Crown      none given  Canada

Note that the last name "Crown" in the last output record is misaligned because there is an extraneous <space> character before "Crown" in your sample input file.