I don't understand what your code was trying to do by setting elements of your C[] array to -9999. Although not tested with the sample input you provided, I assume that you were setting elements of your V[] array to -9999 to give each field a default value if there is no line in an input record for a given field.

The following code gathers field headers from the 1st input record and gathers data from subsequent records ignoring headers (field 1 values) that were not found in the 1st record. If fields are missing from other input records the default value of -9999 will be printed as the value for those fields. The order of fields in the first input record determines the order of fields in all of the output records.

If this is what you were trying to do, the following code is considerably shorter than the code you were using and produces the same output that your code produced when given the DOS text format input file you uploaded as file.txt:

Code:

awk -F': ' '
BEGIN {	OFS = ","
}
/^___/ {if(!r++)
		for(i = 1; i <= n; i++)
			printf("%s%s", h[i], (i == n) ? ORS : OFS)
	for(i = 1; i <= n; i++) {
		printf("%s%s", v[i], (i == n) ? ORS : OFS)
		v[i] = -9999
	}
}
r == 0 {h[++n] = $1
	h2f[$1] = n
}
{	sub(/\r/, "")
	v[h2f[$1]] = $2
}' "${1:-file.txt}" > "${2:-file}.csv"

Note that if you would like to get rid of the trailing space in each field in the header output line, you can do that by changing the line:

Code:

awk -F': ' '

in the script above to:

Code:

awk -F' : ' '

Although I don't have gawk, the above code should work with gawk as well as with awk. If you want to try this on a Solaris/SunOS system, change awk to /usr/xpg4/bin/awk or nawk.