Need help with array substitution Post: 303000286

10 More Discussions You Might Find Interesting

1. Shell Programming and Scripting

Array help (variable substitution).

I am using an array (clmlist01). I have 61 of these and have 4 or more references to each one in a block of code that I do not want to have to hardcode. With that being said, I am creating a varible and going through a for loop to create the actually name of each array. The arrays would end up...

2. Programming

Creating an array to hold posix thread ids: Only dynamic array works

I am facing a strange error while creating posix threads: Given below are two snippets of code, the first one works whereas the second one gives a garbage value in the output. Snippet 1 This works: -------------- int *threadids; threadids = (int *) malloc (num_threads * sizeof(int)); ...

3. Shell Programming and Scripting

Tricky array substitution in functions

Hello, Please tell me if there is a better way to get the number of elements from an array that is passed to a function. This is what works on Solaris 8 (ksh) but it looks odd: loop_array() { array_name=$2 b1='\${\#' b2='}' nr_elements=`eval echo...

4. Shell Programming and Scripting

Difference between "Command substitution" and "Process substitution"

Hi, What is the actual difference between these two? Why the following code works for process substitution and fails for command substitution? while IFS= read -r line; do echo $line; done < <(cat file)executes successfully and display the contents of the file But, while IFS='\n' read -r...

5. Shell Programming and Scripting

Array reference - bad substitution

I've created a series of arrays named as follows: row1 row2 row3 . . . row10 Each has 4 elements. I'm trying to echo the array elements out in a for loop. Here's what I have: for ((i=1;i<=10;i++)) do for ((j=1;j<=4;j++)) do eval out=${row`echo $i`} echo -n $out

6. Shell Programming and Scripting

Substitution in a file dont work with an Array in filename

Hi. I�ve a script that should substitude the 8th line in a file called xxx.num6. The "xxx" is set by an array filled with this command: j=0 for Par in *.sys ; do Par=`echo $Par | sed 's/$.*$.sys/\1/'` ; Par2="$Par" ; echo "${Par2}" j=$((j + 1)); done Now i try...

7. Shell Programming and Scripting

PERL : Read an array and write to another array with intial string pattern checks

I have an array and two variables as below, I need to check if $datevar is present in $filename. If so, i need to replace $filename with the values in the array. I need the output inside an ARRAY How can this be done. Any help will be appreciated. Thanks in advance.

8. Shell Programming and Scripting

Bash 3.2 - Array / Regex - IF 3rd member in array ends in 5 digits then do somthing...

Trying to do some control flow parsing based on the index postion of an array member. Here is the pseudo code I am trying to write in (preferably in pure bash) where possible. I am thinking regex with do the trick, but need a little help. pesudo code if == ENDSINFIVEINTS ]]; then do...

9. Shell Programming and Scripting

Variable substitution in array printing

Hi folks, A really dumb question as I've wasted far too long trying to get this to work.... (on RH bash) I have an array: m0='<hello>' m0='<there>' m0='<fred>' v0='<goodbye>' v0='<again>' v0='<john>' in my code I calculate the value of the variable to output and if I echo it, I...

10. Shell Programming and Scripting

Bash arrays: rebin/interpolate smaller array to large array

hello, i need a bit of help on how to do this effectively in bash without a lot of extra looping or massive switch/case i have a long array of M elements and a short array of N elements, so M > N always. M is not a multiple of N. for case 1, I want to stretch N to fit M arrayHuge H = (...

LEARN ABOUT DEBIAN

mojolicious::guides::rendering

Mojolicious::Guides::Rendering(3pm)			User Contributed Perl Documentation		       Mojolicious::Guides::Rendering(3pm)

NAME

       Mojolicious::Guides::Rendering - Rendering

OVERVIEW

       This document explains content generation with the Mojolicious renderer.

CONCEPTS

       Essentials every Mojolicious developer should know.

   Renderer
       The renderer is a tiny black box turning stash data into actual responses utilizing multiple template systems and data encoding modules.

	 {text => 'Hello.'}		    -> 200 OK, text/html, 'Hello.'
	 {json => {x => 3}}		    -> 200 OK, application/json, '{"x":3}'
	 {text => 'Oops.', status => '410'} -> 410 Gone, text/html, 'Oops.'

       Templates can be automatically detected if enough information is provided by the developer or routes. Template names are expected to follow
       the "name.format.handler" scheme, with "name" defaulting to "controller/action" or the route name, "format" defaulting to "html" and
       "handler" to "ep".

	 {controller => 'users', action => 'list'} -> 'users/list.html.ep'
	 {name => 'foo', format => 'txt'}	   -> 'foo.txt.ep'
	 {name => 'foo', handler => 'epl'}	   -> 'foo.html.epl'

       All templates should be in the "templates" directories of the application or the "DATA" section of the class "main".

	 __DATA__

	 @@ time.html.ep
	 % use Time::Piece;
	 % my $now = localtime;
	 <!DOCTYPE html>
	 <html>
	   <head><title>Time</title></head>
	   <body>The time is <%= $now->hms %>.</body>
	 </html>

	 @@ hello.txt.ep
	 ...

       The renderer can be easily extended to support additional template systems with plugins, but more about that later.

   Embedded Perl
       Mojolicious includes a minimalistic but very powerful template system out of the box called Embedded Perl or "ep" for short. It allows the
       embedding of Perl code right into actual content using a small set of special tags and line start characters.

	 <% Perl code %>
	 <%= Perl expression, replaced with XML escaped result %>
	 <%== Perl expression, replaced with result %>
	 <%# Comment, useful for debugging %>
	 <%% Replaced with "<%", useful for generating templates %>
	 % Perl code line, treated as "<% line =%>"
	 %= Perl expression line, treated as "<%= line %>"
	 %== Perl expression line, treated as "<%== line %>"
	 %# Comment line, treated as "<%# line =%>"
	 %% Replaced with "%", useful for generating templates

       Tags and lines work pretty much the same, but depending on context one will usually look a bit better. Semicolons get automatically
       appended to all expressions.

	 <% my $i = 10; %>
	 <ul>
	   <% for my $j (1 .. $i) { %>
	     <li>
	       <%= $j %>
	     </li>
	   <% } %>
	 </ul>

	 % my $i = 10;
	 <ul>
	   % for my $j (1 .. $i) {
	     <li>
	       %= $j
	     </li>
	   % }
	 </ul>

       Aside from differences in whitespace handling, both examples generate similar Perl code, a naive translation could look like this.

	 my $output = '';
	 my $i = 10;
	 $output .= '<ul>';
	 for my $j (1 .. $i) {
	   $output .= '<li>';
	   $output .= xml_escape scalar $j;
	   $output .= '</li>';
	 }
	 $output .= '</ul>';
	 return $output;

       An additional equal sign can be used to disable escaping of the characters "<", ">", "&", "'" and """ in results from Perl expressions,
       which is the default to prevent XSS attacks against your application.

	 <%= 'lalala' %>
	 <%== '<p>test</p>' %>

       Only Mojo::ByteStream objects are excluded from automatic escaping.

	 <%= Mojo::ByteStream->new('<p>test</p>') %>

       Newlines can be escaped with a backslash.

	 This is <%= 1 + 1 %> a
	 single line

       And a backslash in front of a newline can be escaped with another backslash.

	 This will <%= 1 + 1 %> result\
	 in multiple\
	 lines

       You can also add an additional equal sign to the end of a tag to have it automatically remove all surrounding whitespace, this allows free
       indenting without ruining the result.

	 <% for (1 .. 3) { %>
	   <%= $foo =%>
	 <% } %>

       Stash values that don't have invalid characters in their name get automatically initialized as normal variables in the template, and the
       controller object as $self.

	 $self->stash(name => 'tester');

	 Hello <%= $name %> from <%= $self->tx->remote_address %>.

       There are also many helper functions available, but more about that later.

	 <%= dumper {foo => 'bar'} %>

BASICS

       Most commonly used features every Mojolicious developer should know about.

   Automatic rendering
       The renderer can be manually started by calling the method "render" in Mojolicious::Controller, but that's usually not necessary, because
       it will get automatically called if nothing has been rendered after the router finished its work. This also means you can have routes
       pointing only to templates without actual actions.

	 $self->render;

       There is one big difference though, by calling it manually you can make sure that templates use the current controller object, and not the
       default controller specified with the attribute "controller_class" in Mojolicious.

   Rendering templates
       The renderer will always try to detect the right template but you can also use the "template" stash value to render a specific one.

	 $self->render(template => 'foo/bar');

       Choosing a specific "format" and "handler" is just as easy.

	 $self->render(template => 'foo/bar', format => 'txt', handler => 'epl');

       Because rendering a specific template is the most common task it also has a shortcut.

	 $self->render('foo/bar');

   Rendering inline templates
       Some renderers such as "ep" allow templates to be passed inline.

	 $self->render(inline => 'The result is <%= 1 + 1%>.');

       Since auto detection depends on a path you might have to supply a "handler" too.

	 $self->render(inline => "<%= shift->param('foo') %>", handler => 'epl');

   Rendering text
       Perl characters can be rendered with the "text" stash value, the given content will be automatically encoded to bytes.

	 $self->render(text => 'Hello Woerld!');

   Rendering data
       Raw bytes can be rendered with the "data" stash value, no encoding will be performed.

	 $self->render(data => $octets);

   Rendering JSON
       The "json" stash value allows you to pass Perl structures to the renderer which get directly encoded to JSON.

	 $self->render(json => {foo => [1, 'test', 3]});

   Partial rendering
       Sometimes you might want to access the rendered result, for example to generate emails, this can be done using the "partial" stash value.

	 my $html = $self->render('mail', partial => 1);

   Status code
       Response status codes can be changed with the "status" stash value.

	 $self->render(text => 'Oops.', status => 500);

   Content type
       The "Content-Type" header of the response is actually based on the MIME type mapping of the "format" stash value.

	 $self->render(text => 'Hello.', format => 'txt');

       These mappings can be easily extended or changed with "types" in Mojolicious.

	 # Application
	 package MyApp;
	 use Mojo::Base 'Mojolicious';

	 sub startup {
	   my $self = shift;

	   # Add new MIME type
	   $self->types->type(txt => 'text/plain; charset=utf-8');
	 }

	 1;

   Stash data
       Any of the native Perl data types can be passed to templates through the "stash" in Mojolicious::Controller.

	 $self->stash(author	 => 'Sebastian');
	 $self->stash(frameworks => [qw(Catalyst Mojolicious)]);
	 $self->stash(examples	 => {tweetylicious => 'a microblogging app'});

	 %= $author
	 %= $frameworks->[1]
	 %= $examples->{tweetylicious}

       Since everything is just Perl normal control structures just work.

	 % for my $framework (@$frameworks) {
	   <%= $framework %> was written by <%= $author %>.
	 % }

	 % while (my ($app, $description) = each %$examples) {
	   <%= $app %> is a <%= $description %>.
	 % }

   Content negotiation
       For resources with different representations and that require truly "RESTful" content negotiation you can also use "respond_to" in
       Mojolicious::Controller instead of "render" in Mojolicious::Controller.

	 # /hello (Accept: application/json) -> "json"
	 # /hello (Accept: text/xml)	     -> "xml"
	 # /hello.json			     -> "json"
	 # /hello.xml			     -> "xml"
	 # /hello?format=json		     -> "json"
	 # /hello?format=xml		     -> "xml"
	 $self->respond_to(
	   json => {json => {hello => 'world'}},
	   xml	=> {text => '<hello>world</hello>'}
	 );

       The best possible representation will be automatically selected from the "Accept" request header, "format" stash value or "format" GET/POST
       parameter.

	 $self->respond_to(
	   json => {json => {hello => 'world'}},
	   html => sub {
	     $self->content_for(head => '<meta name="author" content="sri" />');
	     $self->render(template => 'hello', message => 'world')
	   }
	 );

       Callbacks can be used for representations that are too complex to fit into a single render call.

	 # /hello (Accept: application/json) -> "json"
	 # /hello (Accept: text/html)	     -> "html"
	 # /hello (Accept: image/png)	     -> "any"
	 # /hello.json			     -> "json"
	 # /hello.html			     -> "html"
	 # /hello.png			     -> "any"
	 # /hello?format=json		     -> "json"
	 # /hello?format=html		     -> "html"
	 # /hello?format=png		     -> "any"
	 $self->respond_to(
	   json => {json => {hello => 'world'}},
	   html => {template => 'hello', message => 'world'},
	   any	=> {text => '', status => 204}
	 );

       And if no viable representation could be found, the "any" fallback will be used or an empty 204 response rendered automatically.

   Helpers
       Helpers are little functions you can use in templates and controller code.

	 %= dumper [1, 2, 3]

	 my $serialized = $self->dumper([1, 2, 3]);

       The helper "dumper" in Mojolicious::Plugin::DefaultHelpers for example will use Data::Dumper to serialize whatever data structure you pass
       it, this can be very useful for debugging. We differentiate between "default helpers" which are more general purpose like "dumper" and "tag
       helpers", which are template specific and mostly used to generate "HTML" tags.

	 %= javascript '/script.js'

	 %= javascript begin
	   var a = 'b';
	 % end

       A list of all built-in helpers can be found in Mojolicious::Plugin::DefaultHelpers and Mojolicious::Plugin::TagHelpers.

   Layouts
       Most of the time when using "ep" templates you will want to wrap your generated content in a HTML skeleton, thanks to layouts that's
       absolutely trivial.

	 @@ foo/bar.html.ep
	 % layout 'mylayout';
	 Hello World!

	 @@ layouts/mylayout.html.ep
	 <!DOCTYPE html>
	 <html>
	   <head><title>MyApp</title></head>
	   <body><%= content %></body>
	 </html>

       You just select the right layout template with the helper "layout" in Mojolicious::Plugin::DefaultHelpers and place the result of the
       current template with the helper "content" in Mojolicious::Plugin::DefaultHelpers. You can also pass along normal stash values to the
       "layout" helper.

	 @@ foo/bar.html.ep
	 % layout 'mylayout', title => 'Hi there';
	 Hello World!

	 @@ layouts/mylayout.html.ep
	 <!DOCTYPE html>
	 <html>
	   <head><title><%= $title %></title></head>
	   <body><%= content %></body>
	 </html>

       Instead of the "layout" helper you could also just use the "layout" stash value, or call "render" in Mojolicious::Controller with the
       "layout" argument.

	 $self->render(template => 'mytemplate', layout => 'mylayout');

       To set a "layout" stash value application wide you can use "defaults" in Mojolicious.

	 # Application
	 package MyApp;
	 use Mojo::Base 'Mojolicious';

	 sub startup {
	   my $self = shift;

	   # Default layout
	   $self->defaults(layout => 'mylayout');
	 }

	 1;

   Including partial templates
       Like most helpers "include" in Mojolicious::Plugin::DefaultHelpers is just a shortcut to make your life a little easier.

	 @@ foo/bar.html.ep
	 <!DOCTYPE html>
	 <html>
	   %= include 'header'
	   <body>Bar</body>
	 </html>

	 @@ header.html.ep
	 <head><title>Howdy</title></head>

       Instead of "include" you could also just call "render" in Mojolicious::Controller with the "partial" argument.

	 @@ foo/bar.html.ep
	 <!DOCTYPE html>
	 <html>
	   %= $self->render('header', partial => 1)
	   <body>Bar</body>
	 </html>

	 @@ header.html.ep
	 <head><title>Howdy</title></head>

       But there is one small difference between the two, if you pass stash values to "include", they will get localized automatically and are
       only available in the partial template.

	 @@ foo/bar.html.ep
	 <!DOCTYPE html>
	 <html>
	   %= include 'header', title => 'Hello'
	   <body>Bar</body>
	 </html>

	 @@ header.html.ep
	 <head><title><%= $title %></title></head>

   Reusable template blocks
       It's never fun to repeat yourself, that's why you can build reusable template blocks in "ep" that work very similar normal Perl functions.

	 @@ welcome.html.ep
	 <% my $block = begin %>
	   <% my $name = shift; %>
	   Hello <%= $name %>.
	 <% end %>
	 <%= $block->('Sebastian') %>
	 <%= $block->('Sara') %>

       Blocks are always delimited by the "begin" and "end" keywords.

	 @@ welcome.html.ep
	 % my $block = begin
	   % my $name = shift;
	   Hello <%= $name %>.
	 % end
	 % for (1 .. 10) {
	   %== $block->('Sebastian')
	 % }

       A naive translation to Perl code could look like this.

	 @@ welcome.html.pl
	 my $output = '';
	 my $block  = sub {
	   my $name   = shift;
	   my $output = '';
	   $output .= 'Hello ';
	   $output .= xml_escape scalar $name;
	   $output .= '.';
	   return Mojo::ByteStream->new($output);
	 }
	 for (1 .. 10) {
	   $output .= scalar $block->('Sebastian');
	 }
	 return $output;

   Content blocks
       Blocks and the helper "content_for" in Mojolicious::Plugin::DefaultHelpers can also be used to pass whole sections of the template to the
       layout.

	 @@ foo/bar.html.ep
	 % layout 'mylayout';
	 % content_for header => begin
	   <meta http-equiv="Content-Type" content="text/html">
	 % end
	 <div>Hello World!</div>
	 % content_for header => begin
	   <meta http-equiv="Pragma" content="no-cache">
	 % end

	 @@ layouts/mylayout.html.ep
	 <!DOCTYPE html>
	 <html>
	   <head><%= content_for 'header' %></head>
	   <body><%= content %></body>
	 </html>

   Template inheritance
       Inheritance takes the layout concept above one step further, the helpers "content" in Mojolicious::Plugin::DefaultHelpers and "extends" in
       Mojolicious::Plugin::DefaultHelpers allow you to build a skeleton template with named blocks that child templates can override.

	 @@ first.html.ep
	 <!DOCTYPE html>
	 <html>
	   <head><title>Hello</title></head>
	   <body>
	     %= content header => begin
	       Default header
	     % end
	     <div>Hello World!</div>
	     %= content footer => begin
	       Default footer
	     % end
	   </body>
	 </html>

	 @@ second.html.ep
	 % extends 'first';
	 % content header => begin
	   New header
	 % end

       This chain could go on and on to allow a very high level of template reuse.

   Memorizing template blocks
       Compiled templates are always cached in memory, but with the helper "memorize" in Mojolicious::Plugin::DefaultHelpers you can go one step
       further and prevent template blocks from getting executed more than once.

	 @@ cached.html.ep
	 % use Time::Piece;
	 %= memorize begin
	   This template was compiled at <%= localtime->hms %>.
	 % end

   Adding helpers
       Adding and redefining helpers is very easy, you can use them to do pretty much everything.

	 use Mojolicious::Lite;

	 helper debug => sub {
	   my ($self, $string) = @_;
	   $self->app->log->debug($string);
	 };

	 get '/' => sub {
	   my $self = shift;
	   $self->debug('action');
	 } => 'index';

	 app->start;
	 __DATA__

	 @@ index.html.ep
	 % debug 'template';

       Helpers can also accept template blocks as last argument, this for example allows very pleasant to use tag helpers and filters.

	 use Mojolicious::Lite;
	 use Mojo::ByteStream;

	 helper trim_newline => sub {
	   my ($self, $block) = @_;
	   my $result = $block->();
	   $result =~ s/
//g;
	   return Mojo::ByteStream->new($result);
	 };

	 get '/' => 'index';

	 app->start;
	 __DATA__

	 @@ index.html.ep
	 %= trim_newline begin
	   Some text.
	   %= 1 + 1
	   More text.
	 % end

       Wrapping the helper result into a Mojo::ByteStream object can prevent accidental double escaping.

   Helper plugins
       Some helpers might be useful enough for you to share them between multiple applications, plugins make that very simple.

	 package Mojolicious::Plugin::DebugHelper;
	 use Mojo::Base 'Mojolicious::Plugin';

	 sub register {
	   my ($self, $app) = @_;
	   $app->helper(debug => sub {
	     my ($self, $string) = @_;
	     $self->app->log->debug($string);
	   });
	 }

	 1;

       The "register" method will be called when you load the plugin.

	 use Mojolicious::Lite;

	 plugin 'DebugHelper';

	 get '/' => sub {
	   my $self = shift;
	   $self->debug('It works.');
	   $self->render_text('Hello.');
	 };

	 app->start;

       A skeleton for a full "CPAN" compatible plugin distribution can be automatically generated.

	 $ mojo generate plugin DebugHelper

       And if you have a "PAUSE" account (which can be requested at <http://pause.perl.org>), you are only a few commands away from relasing it to
       "CPAN".

	 $ perl Makefile.PL
	 $ make test
	 $ make manifest
	 $ make dist
	 $ mojo cpanify -u USER -p PASS Mojolicious-Plugin-DebugHelper-0.01.tar.gz

   Bundling assets with plugins
       Assets such as templates and static files can be easily bundled with your plugins, even if you plan to release them to "CPAN".

	 $ mojo generate plugin AlertAssets
	 $ mkdir AlertAssets/lib/Mojolicious/Plugin/AlertAssets
	 $ cd AlertAssets/lib/Mojolicious/Plugin/AlertAssets
	 $ mkdir public
	 $ echo 'alert("Hello World!");' > public/alertassets.js
	 $ mkdir templates
	 $ echo '%= javascript "/alertassets.js"' > templates/alertassets.html.ep

       Just append their respective directories to the list of search paths when "register" is called.

	 package Mojolicious::Plugin::AlertAssets;
	 use Mojo::Base 'Mojolicious::Plugin';

	 use File::Basename 'dirname';
	 use File::Spec::Functions 'catdir';

	 sub register {
	   my ($self, $app) = @_;

	   # Append "templates" and "public" directories
	   my $base = catdir(dirname(__FILE__), 'AlertAssets');
	   push @{$app->renderer->paths}, catdir($base, 'templates');
	   push @{$app->static->paths},   catdir($base, 'public');
	 }

	 1;

       Both will work just like normal "templates" and "public" directories once you've installed and loaded the plugin, with slightly lower
       precedence.

	 use Mojolicious::Lite;

	 plugin 'AlertAssets';

	 get '/alert_me';

	 app->start;
	 __DATA__

	 @@ alert_me.html.ep
	 <!DOCTYPE html>
	 <html>
	   <head>
	     <title>Alert me!</title>
	     %= include 'alertassets'
	   </head>
	   <body>You've been alerted.</body>
	 </html>

       And it works just the same for assets bundled in the "DATA" section of your plugin.

	 package Mojolicious::Plugin::AlertAssets;
	 use Mojo::Base 'Mojolicious::Plugin';

	 sub register {
	   my ($self, $app) = @_;

	   # Append class
	   push @{$app->renderer->classes}, __PACKAGE__;
	   push @{$app->static->classes},   __PACKAGE__;
	 }

	 1;
	 __DATA__

	 @@ alertassets.js
	 alert("Hello World!");

	 @@ alertassets.html.ep
	 %= javascript "/alertassets.js"

   Custom "exception" and "not_found" templates
       While the built-in "exception" and "not_found" templates are very useful during development, you most likely want to show your users
       something more related to your application in production. That's why Mojolicious will always try to render "exception.$mode.$format.*" or
       "not_found.$mode.$format.*" before falling back to the built-in default templates.

	 @@ not_found.production.html.ep
	 <!DOCTYPE html>
	 <html>
	   <head><title>Page not found</title></head>
	   <body>Page does not seem to exist.</body>
	 </html>

ADVANCED

       Less commonly used and more powerful features.

   Internationalization
       Thanks to Locale::Maketext all you need for basic internationalization support in your application is the plugin Mojolicious::Plugin::I18N
       and a few lexicon classes.

	 package MyApp::I18N::de;
	 use Mojo::Base -strict;
	 use base 'MyApp::I18N';

	 our %Lexicon = ('Hello World' => 'Hallo Welt');

	 package main;
	 use Mojolicious::Lite;

	 plugin I18N => {namespace => 'MyApp::I18N'};

	 get '/' => 'hello';

	 app->start;
	 __DATA__

	 @@ hello.html.ep
	 <%=l 'Hello World' %>!

       Preferred languages will be automatically detected from the "Accept-Language" header or can be manually changed with the helper "languages"
       in Mojolicious::Plugin::I18N.

	 $ ./myapp.pl get -H 'Accept-Language: de' /

   Chunked transfer encoding
       For very dynamic content you might not know the response "Content-Length" in advance, that's where the "chunked" "Transfer-Encoding" comes
       in handy. A common use would be to send the "head" section of an HTML document to the browser in advance and speed up preloading of
       referenced images and stylesheets.

	 $self->write_chunk('<html><head><title>Example</title></head>', sub {
	   my $self = shift;
	   $self->finish('<body>Example</body></html>');
	 });

       The optional drain callback ensures that all previous chunks have been written before processing continues. An empty chunk or call to
       "finish" in Mojolicious::Controller marks the end of the stream.

	 29
	 <html><head><title>Example</title></head>
	 1b
	 <body>Example</body></html>
	 0

       Especially in combination with long inactivity timeouts this can be very useful for Comet ("long polling"). Due to limitations in some web
       servers this might not work perfectly in all deployment environments.

   Encoding
       Templates stored in files are expected to be "UTF-8" by default, but that can be easily changed.

	 # Application
	 package MyApp;
	 use Mojo::Base 'Mojolicious';

	 sub startup {
	   my $self = shift;

	   # Different encoding
	   $self->renderer->encoding('koi8-r');
	 }

	 1;

       All templates from the DATA section are bound to the encoding of the Perl script, so don't forget to use the utf8 pragma if necessary.

	 use Mojolicious::Lite;
	 use utf8;

	 get '/heart';

	 app->start;
	 __DATA__

	 @@ heart.html.ep
	 I X Mojolicious!

   Base64 encoded DATA files
       Base64 encoded static files such as images can be easily stored in the "DATA" section of your application, similar to templates.

	 @@ favicon.ico (base64)
	 ...base64 encoded image...

   Inflating DATA templates
       Templates stored in files get preferred over files from the "DATA" section, this allows you to include a default set of templates in your
       application that the user can later customize. The "inflate" command will write all templates and static files from the "DATA" section into
       actual files in the "templates" and "public" directories.

	 $ ./myapp.pl inflate

   Customizing the template syntax
       You can easily change the whole template syntax by loading the "ep_renderer" plugin with a custom configuration.

	 use Mojolicious::Lite;

	 plugin EPRenderer => {
	   name     => 'mustache',
	   template => {
	     tag_start => '{{',
	     tag_end   => '}}'
	   }
	 };

	 get '/' => 'index';

	 app->start;
	 __DATA__

	 @@ index.html.mustache
	 Hello {{= $name }}.

       Mojo::Template contains the whole list of available options.

   Adding your favorite template system
       Maybe you would prefer a different template system than "ep", all you have to do is add a new "handler".

	 use Mojolicious::Lite;

	 app->renderer->add_handler(
	   mine => sub {
	     my ($r, $c, $output, $options) = @_;

	     # One time use inline template
	     my $inline = $options->{inline};

	     # Generate relative template path
	     my $name = $r->template_name($options);

	     # Try to find appropriate template in DATA section
	     my $content = $r->get_data_template($options, $name);

	     # Generate absolute template path
	     my $path = $r->template_path($options);

	     # This part is up to you and your template system :)
	     ...

	     # Pass the rendered result back to the renderer
	     $$output = 'The rendered result';

	     # Return true if rendering succeeded and false if it didn't
	     return 1;
	   }
	 );

	 get '/' => 'index';

	 app->start;
	 __DATA__

	 @@ index.html.mine
	 ...

       Since most template systems don't support templates in the "DATA" section the renderer provides methods to help you with that.

MORE

       You can continue with Mojolicious::Guides now or take a look at the Mojolicious wiki <http://github.com/kraih/mojo/wiki>, which contains a
       lot more documentation and examples by many different authors.

perl v5.14.2							    2012-09-05				       Mojolicious::Guides::Rendering(3pm)

10 More Discussions You Might Find Interesting

1. Shell Programming and Scripting

Array help (variable substitution).

Discussion started by: dsimpg1

2. Programming

Creating an array to hold posix thread ids: Only dynamic array works

Discussion started by: kmehta

3. Shell Programming and Scripting

Tricky array substitution in functions

Discussion started by: majormark

4. Shell Programming and Scripting

Difference between "Command substitution" and "Process substitution"

Discussion started by: royalibrahim