Hi wahi80,
Assuming that /mapr/datalake/optum/optuminsight/onepay_dev/fs_dev/raw/pklist/op/part-m-00000 is an empty file, and desc.txt and pk.txt contain the sample input shown in post #1 in this thread, Chubler_XL's code produces the output:

Code:

Employee|id|t1.id=t2.id
Contact|name,phone,country|TRIM(t1.name)=TRIM(t2.name) AND t1.phone=t2.phone AND TRIM(t1.country)=TRIM(t2.country)

Which differs from the output you said you wanted:

Code:

Employee | t1.id=s.id
Contact| TRIM(t1.name)=TRIM(s.name) AND t1.phone=t2.phone AND TRIM(t1.country)=TRIM(s.country)

in the spots marked in red.

I have no idea whether you want two | separated fields in lines in your output (as shown in the output you said you wanted) or three (as created by the code you were using). And, I have no idea why you sometimes have s.field_name and sometimes have t2.field_name in your sample output. And, I have no idea why you seem to want inconsistent field separators in your input and output (sometimes |, sometimes | , and sometimes | ).

The following comes closer to providing the output you said you want, but:

Code:

awk -F "[ |]*" '
BEGIN {	fmt[0] = "%s%s.%s=%s.%s"
	fmt[1] = "%sTRIM(%s.%s)=TRIM(%s.%s)"
}
FNR == NR {
	if($3 == "string")
		trim[$1, $2]
	next
}
FNR > 1 {
	printf("%s|", $1)
	flds = split($2, F, ",")
	for(i = 1; i <= flds; i++)
		printf(fmt[(($1, F[i]) in trim)], (i > 1) ? " AND " : "", S,
		    F[i], D, F[i])
	print ""
}' S=t1 D=t2 desc.txt pk.txt

which produces the output:

Code:

Employee|t1.id=t2.id
Contact|TRIM(t1.name)=TRIM(t2.name) AND t1.phone=t2.phone AND TRIM(t1.country)=TRIM(t2.country)

when given the sample input you provided in post #1.

As always, if someone wants to try this code on a Solaris/SunOS system, change awk to /usr/xpg4/bin/awk or nawk.

I hope this helps,
Don