awk -F "@" '
BEGIN   {FMT1 = "%s%s\tSUM(CASE WHEN T1.%s=T2.%s THEN 1 ELSE 0 END) %s_%s"
         FMT2 = "\nFROM %s T1 INNER JOIN %s T2 ON T1.COLABC=T2.COLABC;\n\n"
        }
        {IX = $1 "," $4 "," $7
         ARR[IX "," ++CNT[IX]] = $2 "_" $5
        }
END     {for (c in CNT) {split  (c, TBL, ",")
                         printf "SELECT "
                         LC = 0
                         LF = DL = ""
                         for (i=1; i<=CNT[c]; i++)      {split (ARR[c "," i], COL, "_")
                                                         printf FMT1, DL, LF, COL[1], COL[2], COL[1], COL[2]
                                                         DL = ","
                                                         LF = "\n"
                                                         if (!(++LC%LNMX) &&
                                                                i<CNT[c])       {printf FMT2, TBL[1], TBL[2] 
                                                                                 printf "SELECT "
                                                                                 DL = LF = ""
                                                                        }
                                                        }
                         printf FMT2, TBL[1], TBL[2] 
                        }
        }
' LNMX=3 file
SELECT 	SUM(CASE WHEN T1.column1=T2.column1 THEN 1 ELSE 0 END) column1_column1,
	SUM(CASE WHEN T1.column3=T2.column3 THEN 1 ELSE 0 END) column3_column3
FROM Table19 T1 INNER JOIN Table29 T2 ON T1.COLABC=T2.COLABC;

SELECT 	SUM(CASE WHEN T1.column2=T2.column2 THEN 1 ELSE 0 END) column2_column2
FROM Table19 T1 INNER JOIN Table29 T2 ON T1.COLABC=T2.COLABC;

SELECT 	SUM(CASE WHEN T1.column1=T2.column1 THEN 1 ELSE 0 END) column1_column1,
	SUM(CASE WHEN T1.column2=T2.column2 THEN 1 ELSE 0 END) column2_column2,
	SUM(CASE WHEN T1.column3=T2.column3 THEN 1 ELSE 0 END) column3_column3
FROM Table11 T1 INNER JOIN Table21 T2 ON T1.COLABC=T2.COLABC;

SELECT 	SUM(CASE WHEN T1.column100=T2.column100 THEN 1 ELSE 0 END) column100_column100,
	SUM(CASE WHEN T1.column101=T2.column101 THEN 1 ELSE 0 END) column101_column101,
	SUM(CASE WHEN T1.column320=T2.column320 THEN 1 ELSE 0 END) column320_column320
FROM Table11 T1 INNER JOIN Table21 T2 ON T1.COLABC=T2.COLABC;