export t="ABC160120XYZ0983920"; perl -ne '/^##transaction\b/ and @t=(); if (/^##transaction\b/ .. /EOT$/){push @t, $_; $f = 1 if /$ENV{t}/;  if (/EOT$/ && $f){print @t; last}}' mad_man.example

#!/usr/bin/env perl

use strict;
use warnings;

my $trans = shift || die "No search paramenters file given\n";
my $haystack = shift || die "Missing data file\n";

my %trans = ();
my @transaction = ();

open my $fh, '<', $trans or die "open $trans: $!\n";
while(<$fh>){
    chomp;
    $trans{$_} = $_;
}
close $fh;

open $fh, '<', $haystack or die "Could not open $haystack: $!\n";
while(<$fh>){
    if(/^##transaction\b/ .. /EOT$/){
        push @transaction, $_;
        if(/EOT$/){
            process_tran();
            @transaction = ();
        }
    }
}
close $fh;

sub process_tran {
    for my $k (keys %trans){
        my $yes = grep /$k/, @transaction;
        if($yes){
            write_tran ("$haystack.$k", \@transaction);
            delete $trans{$k};
            last;
        }
    }
}

sub write_tran {
    my ($save_tran, $tran_ref) =  @_;
    open my $wfh, '>', $save_tran
        or die "Could not write to $save_tran: $!\n";
    print $wfh @{ $tran_ref };
    close $wfh;
}