Realize that I have been up all night trying to help you (and it is now almost 6AM where I am), so I may not be thinking clearly. But, could you please explain why you chose to change the code I suggested:

Code:

			print l[i] > (FILENAME "_" transnum)

to:

Code:

                print l[i] > (/tmp/remedixz.20160120_085021_41222370_1_new "_" transom)

FILENAME is an awk variable holding the name of the current input file. But, /tmp/remedixz.20160120_085021_41222370_1_new is an attempt to divide nothing by the contents of the variable tmp divided by contents of the variable remedixz followed by a syntax error. And since neither tmp nor remedixz have been defined in this awk script, both are treated as a division by zero.

Would you PLEASE just try the following script without changing it:

Code:

#!/bin/ksh
big_file='/tmp/remedixz.20160120_085021_41222370_1'
transnums='/tmp/transnum'

awk -F '~' '
FNR == NR {
	# Gather transaction numbers...
	t[$1]
	tc = FNR
	next
}
{	# Gather transaction lines.
	l[++lc] = $0
}
$1 == "%%YEDTRN" && $3 in t {
	# We have found a transaction number for a transaction that is to be
	# extracted.  Save the transaction number and remove this transaction
	# from the transaction list.
	delete t[transnum = $2]
	file = FILENAME "_" transnum
	tc--
}
/^0000EOT/ {
	# If we have a transaction that is to be printed, print it.
	if(transnum) {
		# Print the transaction.
		for(i = 1; i <= lc; i++)
			print l[i] > file
		close(file)
		printf("Transaction #%s extracted to file %s\n", transnum, file)
		# Was this the last remaining transaction to be extracted?
		if(tc) {# No.  Reset for next transaction.
			lc = 0
			transnum = ""
		} else {# Yes.  Exit.
			exit
		}
	}
}' "$transnums" "$big_file"

Note that this has a few changes to match your latest description of your transaction format, has a typo fixed, and has some minor performance improvements. It also now includes your filenames (which had not been provided before).

If /tmp/transnum contains the single line:

Code:

ABC160120XYZ0983921

and there is a transaction in your big transaction file with that transaction number, it should produce a file named /tmp/remedixz.20160120_085021_41222370_1_ABC160120XYZ0983921 containing that transaction. And, as stated before, if /tmp/transnum contains multiple transaction numbers on separate lines, one invocation of this script will produce an output file for each transaction given.

If this all works, you could also add an END clause to print a list of any transaction numbers that were specified in your transaction numbers file that were not found in your big transactions file.