#!/bin/ksh
# Assign pathnames for 1st three files to be processed...
f1="Object.txt"
f2="Input.txt"
f3="Output.txt"
# If the 4th pathname to be proceseed is an existing regular file, use it;
# otherwise use /dev/null for the 4th file.
[ -f another_object.txt ] && f4="another_object.txt" || f4="/dev/null"

# Invoke awk to process the 4 input files...
awk '
# FNR is the record number of this line in the current file.  So the following
# action group is executed when we see the 1st line of each file we are
# processing...
FNR == 1 {	
	fn++	# Increment the input file number.
}
# Since there is no pattern on this "pattern { action }" group, it is
# executed for each input line found...
{	d[fn, FNR] = $0		# Save the data found on this input line up to,
				# but not including the line terminating
				# <newline> character ($0) in the array d[]
				# indexed by the file number and line number
				# within that file.
	if(FNR > maxline)	# If the line number is higher than we have seen
				# for any of our input files...
		maxline = FNR	# save the highest line number we have seen for
				# later use.
}
# The following section is executed after we have hit the end-of-file on all
# of our input files...
END {	# Run the following group of 1 command in a loop with i set to 1 the 1st
	# time throught the loop (i = 1), continuing while i is less than or
	# equal to the saved highest input line number (i <= maxline), and
	# incrementing i by one at the end of each pass through the loop (i++).
	for(i = 1; i <= maxline; i++) {
		# Print the following specified values on one line terminated by
		# a <newline> character each time through the loop...
		print d[1, 1],	# the data found in the 1st file on line 1
			# if there was a line number i in the 2nd file ((2, i)
			# in d), print the data found in file 2, line number i
			# (d[2, i]); otherwise print the string NA ("NA").
			(2, i) in d ? d[2,i] : "NA",
			# if there was a line number i in the 3rd file ((3, i)
			# in d), print the data found in file 3, line number i
			# (d[3, i]); otherwise print the string NA ("NA").
			(3, i) in d ? d[3, i] : "NA",
			# if there was a line number i in the 4th file ((4, i)
			# in d), print the data found in file 4, line number i
			# (d[4, i]); otherwise print the string NA ("NA").
			(4, i) in d ? d[4, i] : "NA"
	}
# End this awk script and specify that the output field separator to be used
# when printing lines is a comma (OFS=,) and the pathnames of the 4 input files
# to be processed by this script.
}' OFS=, "$f1" "$f2" "$f3" "$f4"

man awk