I am having trouble following the logic of your script.

The diagnostic you are getting is because the sequence x(i) is a request to call the function named x with the parameter i, you haven't defined any functions, and the function x is not one that is defined by gawk. Furthermore, you can't have a variable and a function with the same name.

Note that the statement: x==0; is a logical expression (not an assignment statement) returning the value 1 if the variable x is zero or an empty string; otherwise it returns 0. (Note that the value of that logical expression doesn't affect the behavior of this script in any way; it does not assign a value to x.)

Although the gawk statement:

Code:

   a=split($2,b,"");

splits the 2nd input field into the array b[] with each element of b[] being set to one character from that field and sets a to the number of characters found; using an empty string as an ERE specifying the field delimiter is not available in all versions of awk (including the one I am using on OS X).

You might want to try something more like:

Code:

awk '
BEGIN {	FS = OFS = "|"	# Set input and output field separators.
}
{	# Initialize the accumulated sum and the current input number to zero.
	sum = number = 0
	print "Processing input: " $2
	end = length($2)
	# Process each character in the 2nd field from left to right...
	for(i = 1; i <= end; i++) {
		if((c = substr($2, i, 1)) ~ /[0-9]/)
			# We found a digit, add it to the current number.
			number = number * 10 + c
		else {	# If it is not a digit it must be a + or -...
			if(c == "+")
				# We found a +, add number to sum.
				sum += number
			else
				# Assume we found a minus sign; subtract number
				# from sum.
				sum -= number
			# We are now ready to look for the next number.
			number = 0
		}
	}
	# Print the results...
	print $1, sum
}' file

which, if file contains:

Code:

rec_10|1+2+2-
rec_20|10+12-8+4+
rec_30|1+10+100-1000+
rec_40|1-10-100+1000-

produces the output:

Code:

Processing input: 1+2+2-
rec_10|1
Processing input: 10+12-8+4+
rec_20|10
Processing input: 1+10+100-1000+
rec_30|911
Processing input: 1-10-100+1000-
rec_40|-911

This was tested using awk on OS X, but should also work with gawk on any Linux system.

If someone wants to try this script on a Solaris/SunOS system, change awk to /usr/xpg4/bin/awk or nawk.