You might want to try something like the following:

Code:

awk '
BEGIN {	FS = OFS = "|"
}
FNR == NR {
	hd[$0] = ++hc
	next
}
FNR == 1 {
	for(i = 1; i <= NF; i++)
		if($i in hd)
			of[hd[$i]] = i
}
{	for(i = 1; i <= hc; i++)
		printf("%s%s", $of[i], i == hc ? ORS : OFS)
}' ctrl2 source

but with your latest sample data as shown in post #5, it will give you output similar to:

Code:

ename|eid|esal|awk: illegal field $(), name "4"
 input record number 1, file source
 source line number 14

because the 4th line in the 2nd version of your control file (ecity) does not appear as a header in your source file (it is city instead).

If we change the control file to:

Code:

ename
eid
esal
city

it produces the output:

Code:

ename|eid|esal|city
peter|10|$2000|melbourne
shaun|11|$1000|sydney

which seems like logical output for the input you provided although it doesn't match what you said you wanted (with ecity instead of city again).

You haven't told us what operating system or shell you're using. If you want to try this script on a Solaris/SunOS system, change awk to /usr/xpg4/bin/awk or nawk.