I'm sorry that you feel that way.

In this forum, we try to help people learn how to use the common tools provided on their system to do what they're trying to do; not just provide complete scripts.

When I make a suggestion on how to do something, I try to provide a script that will take sample input provided by the submitter (but there was none in this case) that will produce output that exactly matches the desired output specified by the submitter. While I could make up sample input data and write a script that would produce the sample output you provided, it would not match the description you provided for what you said you wanted to do. And the specification of what you wanted for output for missing fields (with no example output for that case) was ambiguous.

If you had answered any of my questions or had shown that you had tried to fix RudiC's suggested code to more exactly meet your requirements, I would have suggested that you try something like:

Code:

awk '
BEGIN {	# Set search pattern:
	pat = "^From |^From: |^Subject: |^Message-Id: |^Date: |^To: "
	# Extract mail message headers from search pattern...
	nh = split(pat, h, "|")
	for(i = 1; i <= nh; i++) {
		# Remove ">" and " " from the headers:
		gsub(/[ ^]/, "", h[i])
		# Set field to be printed for missing headers:
		b[i] = sprintf("%s \"Blank\"", h[i])
	}
}
function dump() {
	# Function to print headers from a mail message...
	printf("File: \"%s\" message #%d\n", FILENAME, ++msgcnt)
	for(i = 1; i <= nh; i++)
		if(h[i] in d) {
			printf("%s%s", d[h[i]], i == nh ? "\n" : "\t")
			delete d[h[i]]
		} else	printf("%s%s", b[i], i == nh ? "\n" : "\t")
}
FNR == 1 {
	# 1st line of new file found, print final results from previous file
	# and reset counters for this file.
	if(found)
		# Print headers from last mail message in previous file...
		dump()
	found = msgcnt = 0
}
/^From / && found++ {
	# Print headers from previous mail message...
	dump()
}
$0 ~ pat {
	# Gather data from current mail message...
	d[$1] = $0
}
END {	# Print headers from last mail message...
	if(found)
		dump()
}' inbox1 inbox2 inbox3...

Which produces output that I believe matches what you described in post #1 (except that it also outputs a line showing the file from which each message came and the sequence number within that file in case you want to process more than one file at a time) and makes a guess at the output you wanted for missing fields. I could also produce a 1-liner version of it, just to show that it can be done, but it wouldn't help people trying to learn how to write code to give them something that looks like it was intended to be an obfuscated code contest entry:

Code:

awk 'BEGIN{e="^From |^From: |^Subject: |^Message-Id: |^Date: |^To: ";n=split(e,h,"|");for(i=1;i<=n;i++){gsub(/[ ^]/,"",h[i]);b[i]=sprintf("%s \"Blank\"",h[i])}}function p(){printf("File: \"%s\" message #%d\n",FILENAME,++c);for(i=1;i<=n;i++)if(h[i] in d){printf("%s%s",d[h[i]],i==n?"\n":"\t");delete d[h[i]]}else printf("%s%s",b[i],i==n?"\n":"\t")}FNR==1{if(f)p();f=c=0}/^From /&&f++{p()}$0~e{d[$1]=$0}END{if(f)p()}' inbox1 inbox2 inbox3...

As I said before, if there someone showed me code like the above 1-liner and asked me to help them fix it; I would tell them to find someone else to clean up their mess.

As always, with either of these scripts, if you want to try this on a Solaris/SunOS system, change awk to /usr/xpg4/bin/awk or nawk.