You haven't said what OS you're using, but when I tried pravin27's code on OS X, I get a syntax error (probably from missing format arguments for the printf statements).

The following seems to do what you want with any number of fields you want to process (just update the fields[] array initialized in the BEGIN clause AND be sure that you have one lookup file for each field to be updated, one or more subfields in each field being processed, and every subfield appearing in the appropriate Lookupxxx file:

Code:

awk '
BEGIN { FS = OFS = "\t"
        fields[++nf] = 2
        fields[++nf] = 3
        fields[++nf] = 4
}
FNR == 1 {
        f++
}
f <= nf {l[f, $1] = $2
        next
}
{       for(i = nf; i > 0; i--) {
                n = split($fields[i], sf, " ")
                af = OFS
                for(j = 1; j <= n; j++)
                        af = af l[i, sf[j]] ((j < n) ? " " : "")
                $fields[i] = $fields[i] af
        }
}
1' Lookup2 Lookup3 Lookup4 file

If you don't set elements in the fields[] array in increasing numeric order and provide Lookupxxx files in the same order as the order of the elements in the fields[] array, it will not work correctly. If you want to try this on a Solaris/SunOS system, change awk to /usr/xpg4/bin/awk, /usr/xpg6/bin/awk, or nawk.

With your sample Lookup* files and file containing:

Code:

1	a b	x y	hhghd ghgf
2	v t	f g	gdgdgdg hghg
3	a b v t	f	gdgdgdg

it produces the output:

Code:

1	a b	10 20	x y	50 60	hhghd ghgf	90 100
2	v t	30 40	f g	70 80	gdgdgdg hghg	110 120
3	a b v t	10 20 30 40	f	70	gdgdgdg	110