Since your code_to_value.txt file only contains 17 characters per line (not counting the terminating <newline> character), the cut calls creating the files value_1 and value_2 always produce empty files. So, even if the calls to paste work, the files code_1, code_2, and code_3 will also always be empty files.

When I run your code on OS X, I get errors from all of your invocations of paste instead of errors from sed. Bur rather than invoking cat nine times, cut, grep, and paste twelve times, and sed four times; the following script using a single invocation of awk seems to do what you said you wanted done (without using the file list.txt).

Code:

awk '
FNR == NR {
	list[$1] = ++listc
	code[listc, 1] = $2 $2
	code[listc, 2] = $2 $3
	code[listc, 3] = $3 $3
	next
}
{	for(i = 2; i <= NF; i++)
		$i = code[list[$1], $i]
	print
}' code_to_value.txt table_values.txt > test_output

With your sample code_to_value.txt and table_values.txt input files, it produces the output:

Code:

PT_0000000001 AA AA AA AA AA AA AG AG AA AA AG
PT_0000000002 GT GT TT GG GT TT GT GT GG TT GG
PT_0000000003 GG CG GG CG GG GG CG CC CC CG GG
PT_0000000004 CC AC AA AC CC AA CC AC AA AA AC

rather than the output you said you wanted:

Code:

PT_0000000001 AA AG AA AA AA AA AG AG AA AA AG 
PT_0000000002 GG GT TT GG GT TT GT GT GG TT GG
PT_0000000003 GG CG GG CG GG GG CG CC CC CG GG
PT_0000000004 AC AC AA AC CC AA CC AC AA AA AC

If I understand your requirements correctly, I believe the output shown in red in the output you said you were trying to get is inconsistent with your requirements.

Note that if you input files have Windows <carriage-return><line-feed> line terminators instead of UNIX and Linux <newline> line terminators, you'll need to change the line:

Code:

awk '

in the above script to something like:

Code:

awk '
{	gsub(/\r/, "")
}

to get rid of the extraneous <carriage-return> characters.

I hope this helps.