Your sample date changes things a bit:

Code:

use strict;
use warnings;
use Time::Local;

sub ckdate {
   my $date = shift @_;
   my ($year, $mon, $mday) = $date =~ m{^(\d\d\d\d)(\d\d)(\d\d)$};
   return unless defined $mday;
   return defined eval { timegm(0, 0, 0, $mday, $mon-1, $year); };
}

$, = ' ';
$\ = "\n";

while (<>) {
   chomp;
   my @F = split ',';
   next if ckdate pop @F;
   print '?', $_;
}

So what is happening:

Code:

sub ckdate {

A function that will return true if the first argument is a valid date.

Code:

   my $date = shift @_;
   my ($year, $mon, $mday) = $date =~ m{^(\d\d\d\d)(\d\d)(\d\d)$};

Split the date (first argument) into its year, month, and day of the month

Code:

   return unless defined $mday;

Return undef if the date was not of the form YYYYMMDD

Code:

   return defined eval { timegm(0, 0, 0, $mday, $mon-1, $year); };

timegm converts its arguments into a number of seconds of the epoch, of undef if the arguments are invalid. The 'eval' suppresses warning messages.

Code:

   my @F = split ',';

Split the line into comma separated fields

Code:

   next if ckdate pop @F;

Skip to the end of the loop if ckdate returns true: the last field was a valid date.

Code:

    print '?', $_;

Print something to indicate that the date is invalid.

Additional checks could be made to further validate the date field, depending on your requirements. For instance, if this is a table of expirations, then dates in the past would be invalid.

Hope this helps.

Of course, there are many other way to validate dates, I just used a library function.