#!/bin/bash
keep_above=1
keep_below=1
# cleanup - rename selected files and remove others
# Usage: cleanup file_to_rename...
#
# Select a list of all files in the current directory whose names start and
# end with a decimal digit (files with a leading zero in their name will be
# ignored).  Rename each file named as an operand by prefixing it with
# "tested-".  Leave other files in the range:
#    (file_to_rename - $keep_below) <= name <= (file_to_rename + $keep_above)
# for any given operand unchanged.  Remove all other selected files.

IAm=${0##*/}
if [ $# -lt 1 ]
then    printf 'Usage: %s file_to_move...\n' "$IAm" >&2
        exit 1
fi
printf '%s\n' "$@" "EndOfRenameList" [1-9]*[0-9] |
awk -v above="$keep_above" -v below="$keep_below" '
/EndOfRenameList/ {
        eval=1
        next
}
!eval { for(i = $1 - below; i <= ($1 + above); i++)
                keep[i]
        rename[$1]
        next
}
{       if($1 in rename) {
                printf("mv \"%s\" \"tested-%s\"\n", $1, $1)
                delete rename[$1]
        } else if($1 in keep)
                printf("printf \"keeping %s\\n\"\n", $1)
        else    printf("rm -rf \"%s\"\n", $1)
}
END {   for(i in rename) {
                printf("printf \"File \\\"%s\\\" not found.\\n\" >&2\n", i)
                printf("printf \"ec=2\\n\"\n")
        }
        printf("exit \$ec\n")
}' | bash -x