$ cat file
CI Ref,SerialNumber,Last Report Time
VMware-42 2b cb d6 e7 36 ec 73-f4 77 bd 2b f2 6f 25 5d,VMware-42 2b cb d6 e7 36 ec 73-f4 77 bd 2b f2 6f 25 5d,"Fri, 30 May 2014 12:23:13 +0000"
VMware-42 2b 79 e0 da 18 2e 9e-17 b2 6e e1 67 df 3c 6b,VMware-42 2b 79 e0 da 18 2e 9e-17 b2 6e e1 67 df 3c 6b,"Fri, 30 May 2014 12:26:08 +0000"

$ cat addheader
#!/bin/bash

cat >header<<EOF
before=1
CI Name=<blank>
CI Description=<blank>

after=3
abc=<blank>
EOF

awk '

BEGIN{
	file="header"; OFS=","

	while(getline line <file)
	{
		split(line,Arr,/=/)

		if(tolower(Arr[1])=="before")
		{
			key = "b"  
			n = Arr[2] 
			continue
		}
		else if(tolower(Arr[1])=="after")
		{
			key = "a" 
			n = Arr[2] 
			continue
		}	
		
		
		if(length(line))
		{
			H[n FS key FS 1] = ((n FS key FS 1) in H) ? H[n FS key FS 1] OFS Arr[1] : Arr[1]
			H[n FS key FS 0] = ((n FS key FS 0) in H) ? H[n FS key FS 0] OFS Arr[2] : Arr[2]
		}
	}
	close(file)


    }

    {
	c=0 ; str = ""
	$0 = $0","                                   
	while($0) {
  			match($0,/ *"[^"]*" *,|[^,]*,/) 
  			f=substr($0,RSTART,RLENGTH)             
  			gsub(/,$/,"",f)               
			c++  		
		
			if(length(f))
			{
			ind = FNR==1 ? FNR : 0			
			
			f = ((c FS "a" FS ind) in H) ? \
			    f OFS H[c FS "a" FS ind] : f

			f = ((c FS "b" FS ind) in H) ? \
			    H[c FS "b" FS ind] OFS f : f
			    
			str = str == "" ? f : str OFS f
			}
			
  			$0 = substr($0,RLENGTH+1)                
		  }

		if(length(str))print str
    }
   ' file 

$ bash addheader
CI Name,CI Description,CI Ref,SerialNumber,Last Report Time,abc
<blank>,<blank>,VMware-42 2b cb d6 e7 36 ec 73-f4 77 bd 2b f2 6f 25 5d,VMware-42 2b cb d6 e7 36 ec 73-f4 77 bd 2b f2 6f 25 5d,"Fri, 30 May 2014 12:23:13 +0000",<blank>
<blank>,<blank>,VMware-42 2b 79 e0 da 18 2e 9e-17 b2 6e e1 67 df 3c 6b,VMware-42 2b 79 e0 da 18 2e 9e-17 b2 6e e1 67 df 3c 6b,"Fri, 30 May 2014 12:26:08 +0000",<blank>

<before|after>=field number
header_name1 = value1
header_name2 = value2