Since the OP says that file1.txt and file2.txt actually does have BOLD tags (i.e., [B] and [/B]) in the data to mark the digit strings to be matched and awk's match function will treat those tags in the variable i as matching expressions instead of as literal text, RudiC's code doesn't seem to work. I didn't get any output from pravin27's perl script either (I assume for the same reason, but haven't dug into it.) And given that we have been shown lines with "VPN ACC" and some with "VPNACC" and some lines with "KCC script," and some lines with "ID = <digit_string>,", I'm not confident that the bolded string will always be in field 25 in file1.txt. Note also that the OP said he was looking for _ and 3 or 4 digits (not just 3) in file2.txt following the matching bolded digit string (but none of the sample input had 4 digits).

The following seems to work in my tests, but we could probably do something more efficient if we had a better definition of the input file record formats:

Code:

awk '
BEGIN { bds = "[[]B[]]([0-9])+[[]/B[]]" # ERE to match a bolded digit string.
}
# If a line in the 1st file ...
FNR == NR {
        # contains a bolded string of digits, save that bolded string.
        if(match($0, bds))
                bs[substr($0, RSTART, RLENGTH)]
printf("NR=%d, bs[%s] created\n", NR, substr($0, RSTART, RLENGTH))
        next
}
# If a line in the 2nd input file contains a bolded string followed by an
# underscore, 3 or 4 digits, and a space...
/[[]\/B[]]_([0-9]){3,4} / {
        # print the line if the bolded digit string in this line appeared in
        # the first file.
        if(match($0, bds) && substr($0, RSTART, RLENGTH) in bs) print
}' file1.txt file2.txt

With the sample data given in message #3 in this thread, it produces the output:

Code:

NR=1, bs[193708] created
NR=2, bs[15819] created
NR=3, bs[15820] created
< (VPN) 999993080285668, (VPNPRO) mtel-MVPN_(VPNACC) 15819_200 >
< (VPN) 999993080285669, (VPNPRO) mtel-MVPN_(VPNACC) 15820_201 >

Note that the bold text in the output above is from BOLD tags in file1.txt and file2.txt; not from me massaging the output HTML to highlight the matched fields as they are displayed in this forum. The printf statement shown in red in the script is a debugging aid that produces the text in red in the output. Remove the printf to get just the output requested.

As always, if you want to run this on a Solaris/SunOS system, change awk to /usr/xpg4/bin/awk, /usr/xpg6/bin/awk, or nawk.

I am still not confidant that this will work. If relatively long lines are split (as they were in the 1st message in this thread (but not in the 3rd message in this thread), there is nothing to prevent the bolded string from being split across two lines in file1.txt. I could modify the script to work even if this happens, but given the poor specification of input file formats, I didn't take the extra time to do that.