Originally Posted by Don Cragun

Please get into the habit of using indentation to show the structure of your code. It makes it a lot easier for humans to see what you're trying to do even if the awk interpreter (and the Korn shell) don't much care about spacing in the scripts they process (as long as reserved words are separated as required by their lexical analyzers).

I guess I confused you by separating the format string used by printf() to format its output from the printf() statement itself. Please look at your system's man page for the awk utility and look closely at its description of the awk printf() function.

As had been mentioned before, $dd in awk is not a reference to an awk variable named dd, it is a reference to the contents of the field specified by the numeric value of the contents of the awk variable dd. References to variables in the awk programming language and references to variables in the shell programming language are different. So, $dd (when dd contains 2013/03/07) is not valid; but, even if it was, $dd inside quotes in the format string will print the literal string $dd not the contents of the dd'th field in the current input line (which has no defined meaning in the END clause).

Try the following:

Code:

#!/bin/ksh
printf "Enter the date (YYYY/MM/DD): "
read dd
awk -F '[ :]' -v dd="$dd" '
$1 == dd && /successful/ {
        s[$2 + 0, $3 > 29]++
        t++
}
END {   for(h = 0; h < 24; h++)
                for(m = 0; m <= 1; m++)
                        printf("Batches that were successful on %s between %02d:%02d:00 and %02d:%02d:59 : %d\n",
                                dd, h, m * 30, h, m * 30 + 29, s[h, m])
        dl =  "----------------------------------------------------------------"
        printf("%s\nTotal Batches that were sucessful on %s: %d\n%s\n",
                dl, dd, t, dl)
}' log

I would normally split that format string into two parts (so my script would be easily readable on an 80 column output device:

Code:

                        printf("Batches that were successful on %s between " \
                                "%02d:%02d:00 and %02d:%02d:59 : %d\n",
                                dd, h, m * 30, h, m * 30 + 29, s[h, m])

but I didn't want to confuse you by splitting the format string into two parts.