Login or Register to Ask a Question and Join Our Community

Sponsored Content
Full Discussion: Help Me With the Loop.
Top Forums Shell Programming and Scripting Help Me With the Loop. Post 302853519 by Don Cragun on Saturday 14th of September 2013 10:25:56 PM
Old 09-14-2013
Hi nirjhar17,
To get the output you said you wanted in the 3rd message in this thread (except for inconsistent spacing in the output you showed in the symmask commands), the following shell and awk script seems to do what you want. This script will work with any POSIX conforming shell (including bash and ksh). The sed command you gave in your script didn't work on OS X, so I built it into the awk script. (I assume that the file /tmp/devices contains:
Code:
29ce 0B7
1ec8        0B8
1ed1        0B9
1eda 0BA
1ed0 0BB
3aa1        0BC

from what you said you wanted in the symmask commands. But, one of the symmask commands shows one space in the 1st line and the other symmask command shows two spaces in the 1st line???)

Anyway, with the script:
Code:
#!/bin/bash
hostname="testhost"     # This variable was used but not defined in the sample.
# Note that following prompts are written to stderr, not stdout; stdout is going
# into awk.
# Gather the user supplied input:
(       # Create subshell to feed all printf output from this subshell to awk.
printf 'enter the sid for DMX: ' >&2
read SID
printf "%s\n" "$SID"    # Pass SID to awk...
# Determine number of ports to be processed...
printf 'enter the number of ports: ' >&2
read N
for ((i = 1; i <= N; i++))
do      # Prompt for and read dirtor, port, and wwn for this port...
        printf "enter director $i: " >&2
        read DIR
        printf "enter port number $i: " >&2
        read PORT
        printf "enter wwn associted with director $DIR port $PORT: " >&2
        read WWN
        # pass DIR PORT, & WWN to awk...
        printf "%s %s %s\n" "$DIR" "$PORT" "$WWN"
done ) | awk '
# Get sid from start of script above.
NR == 1 {
        sid = $0
        next
}
# Read output written by above shell for loop into awk arrays...
FNR == NR {
        dir[++np] = $1  # director for port NR
        port[np] = $2   # port for port NR
        wwn[np] = $3    # wwn for port NR
        next
}
# Read data from /tmp/devices...
{       devs = nd == 0 ? $0 : devs "," $0
        dev[++nd] = $1
}
# Print the commands associated with the accumulated data...
END {   for(i = 1; i <= np; i++) {
                for (j = 1; j <= nd; j++) {
                        # Print symdev commands...
                        printf("%s -sid %s write_disable %s -SA %s -p %s\n",
                                "/usr/symcli/bin/symdev",
                                sid, dev[j], dir[i], port[i])
                }
        }
        printf("##Device Unmap##\n")
        for(i = 1; i <= np; i++) {
                for (j = 1; j <= nd; j++) {
                        # Print unmap commands...
                        printf("unmap dev %s from dir %s:%s;\n",
                                dev[j], dir[i], port[i])
                }
        }
        print ""
        for(i = 1; i <= np; i++)
                # Print symmask commands...
                printf("%s -sid %s -wwn  %s -dir %s -p %s remove devs %s\n",
                        "symmask", sid, wwn[i], dir[i], port[i], devs)

}' - /tmp/devices > /tmp/"$hostname"

(If you want to run this on a Solaris/SunOS system, use /usr/xpg4/bin/awk, /usr/xpg6/bin/awk, or nawk instead of awk.)

With the prompts (shown in black) and the responses (shown in blue):
Code:
enter the sid for DMX: 4002
enter the number of ports: 2
enter director 1: 4B
enter port number 1: 0
enter wwn associted with director 4B port 0: 2100001b3283a261
enter director 2: 13B
enter port number 2: 0
enter wwn associted with director 13B port 0: 2100001b32832954

the output stored in /tmp/"$hostname" is:
Code:
/usr/symcli/bin/symdev -sid 4002 write_disable 29ce -SA 4B -p 0
/usr/symcli/bin/symdev -sid 4002 write_disable 1ec8 -SA 4B -p 0
/usr/symcli/bin/symdev -sid 4002 write_disable 1ed1 -SA 4B -p 0
/usr/symcli/bin/symdev -sid 4002 write_disable 1eda -SA 4B -p 0
/usr/symcli/bin/symdev -sid 4002 write_disable 1ed0 -SA 4B -p 0
/usr/symcli/bin/symdev -sid 4002 write_disable 3aa1 -SA 4B -p 0
/usr/symcli/bin/symdev -sid 4002 write_disable 29ce -SA 13B -p 0
/usr/symcli/bin/symdev -sid 4002 write_disable 1ec8 -SA 13B -p 0
/usr/symcli/bin/symdev -sid 4002 write_disable 1ed1 -SA 13B -p 0
/usr/symcli/bin/symdev -sid 4002 write_disable 1eda -SA 13B -p 0
/usr/symcli/bin/symdev -sid 4002 write_disable 1ed0 -SA 13B -p 0
/usr/symcli/bin/symdev -sid 4002 write_disable 3aa1 -SA 13B -p 0
##Device Unmap##
unmap dev 29ce from dir 4B:0;
unmap dev 1ec8 from dir 4B:0;
unmap dev 1ed1 from dir 4B:0;
unmap dev 1eda from dir 4B:0;
unmap dev 1ed0 from dir 4B:0;
unmap dev 3aa1 from dir 4B:0;
unmap dev 29ce from dir 13B:0;
unmap dev 1ec8 from dir 13B:0;
unmap dev 1ed1 from dir 13B:0;
unmap dev 1eda from dir 13B:0;
unmap dev 1ed0 from dir 13B:0;
unmap dev 3aa1 from dir 13B:0;

symmask -sid 4002 -wwn  2100001b3283a261 -dir 4B -p 0 remove devs 29ce 0B7,1ec8        0B8,1ed1        0B9,1eda 0BA,1ed0 0BB,3aa1        0BC
symmask -sid 4002 -wwn  2100001b32832954 -dir 13B -p 0 remove devs 29ce 0B7,1ec8        0B8,1ed1        0B9,1eda 0BA,1ed0 0BB,3aa1        0BC

The difference between this output and the output you said you wanted is:
Code:
27c27
< symmask -sid 4002 -wwn  2100001b3283a261 -dir 4B -p 0 remove devs 29ce 0B7,1ec8        0B8,1ed1        0B9,1eda 0BA,1ed0 0BB,3aa1        0BC
---
> symmask -sid 4002 -wwn  2100001b3283a261 -dir 4B -p 0 remove devs 29ce  0B7,1ec8        0B8,1ed1        0B9,1eda 0BA,1ed0 0BB,3aa1        0BC

In addition to producing the output you said you wanted, since this script has one invocation of awk (instead of six invocations of cat, two invocations of sed, and four invocations of awk), it should also run a little bit faster.
This User Gave Thanks to Don Cragun For This Post:
nirjhar17
 

10 More Discussions You Might Find Interesting

1. Shell Programming and Scripting

Is there a better way I could have run this loop. (For loop with two variables)

Sorry for such a dreadful title, but I'm not sure how to be more descriptive. I'm hoping some of the more gurutastic out there can take a look at a solution I came up with to a problem, and advice if there are better ways to have gone about it. To make a long story short around 20K pieces of... (2 Replies)
Discussion started by: DeCoTwc
2 Replies

2. Shell Programming and Scripting

Using variables created sequentially in a loop while still inside of the loop [bash]

I'm trying to understand if it's possible to create a set of variables that are numbered based on another variable (using eval) in a loop, and then call on it before the loop ends. As an example I've written a script called question (The fist command is to show what is the contents of the... (2 Replies)
Discussion started by: DeCoTwc
2 Replies

3. Shell Programming and Scripting

Null Handling in Until loop. . .loop won't stop

Hi Im running this script, which is supposed to find the max value build some tables and then stop running once all the tables are built. Thing is , it keeps assigning a null value to $h and then $g is null so it keep building tables i.e. testupdateNUL. How can I stop this? Here is what I have: ... (4 Replies)
Discussion started by: brandono66
4 Replies

4. Shell Programming and Scripting

BASH loop inside a loop question

Hi all Sorry for the basic question, but i am writing a shell script to get around a slightly flaky binary that ships with one of our servers. This particular utility randomly generates the correct information and could work first time or may work on the 12th or 100th attempt etc !.... (4 Replies)
Discussion started by: rethink
4 Replies

5. Shell Programming and Scripting

S# in a for loop - concatenate $(loop counter)

Hi, hope I am posting in the right section. My problem is that I have 2 or more arguments passed and I want to check if the arguments passed exists or not. The first argument should not exist and the remaining others should exist. example: ./shells.sh argument1 argument2 argument3 ... (5 Replies)
Discussion started by: fight4love
5 Replies

6. Shell Programming and Scripting

My for loop decides to become an infinite loop?

Hi, I was debating if I should put this in the dummies or scripts section, I apologize in advance if I chose poorly. Fairly new to Unix and BASH scripting but I thought I made it fairly well given my limited understanding. However, the output indicates that it's looping and I'm ending up with a... (5 Replies)
Discussion started by: gotreef
5 Replies

7. Shell Programming and Scripting

Array Variable being Assigned Values in Loop, But Gone when Loop Completes???

Hello All, Maybe I'm Missing something here but I have NOOO idea what the heck is going on with this....? I have a Variable that contains a PATTERN of what I'm considering "Illegal Characters". So what I'm doing is looping through a string containing some of these "Illegal Characters". Now... (5 Replies)
Discussion started by: mrm5102
5 Replies

8. Shell Programming and Scripting

Reset while loop to loop same file multiple times

Hi, I want to read file multiple times. Right now i am using while loop but that is not working. ex. While read line do while read line2 do echo stmt1 #processing some data based on data., done < file2.txt done < file1.txt # This will have 10... (4 Replies)
Discussion started by: tmalik79
4 Replies

9. Shell Programming and Scripting

awk loop using array:wish to store array values from loop for use outside loop

Here's my code: awk -F '' 'NR==FNR { if (/time/ && $5>10) A=$2" "$3":"$4":"($5-01) else if (/time/ && $5<01) A=$2" "$3":"$4-01":"(59-$5) else if (/time/ && $5<=10) A=$2" "$3":"$4":0"($5-01) else if (/close/) { B=0 n1=n2; ... (2 Replies)
Discussion started by: klane
2 Replies

10. Shell Programming and Scripting

For loop or while loop from a text file

Hi all, i developed a script to measure the uptime of a process in a Solaris 10/11 environments. All is well, but i came across a situation where there are multiple processes of the same name. Basically i have the following result file: beVWARS 13357 19592122 beVWARS 14329 19591910... (4 Replies)
Discussion started by: nms
4 Replies
All times are GMT -4. The time now is 09:01 AM.
Unix & Linux Forums Content Copyright 1993-2022. All Rights Reserved.
Privacy Policy