awk '
function check(         cn, i, j, ln) {    
        # local variables:   
        #   cn  sequence column number within line
        #   i   loop control
        #   j   loop control
        #   ln  sequence line number

        # Loop through the list of entries from the position file... 
        for(i = 1; i <= sc; i++) {
                if(f[2] != id[i]) continue      # Different Id?  Then go on.
                # Calculate column and line corresponding to position.
                cn = (pos[i] - 1) % 60 + 1
                ln = int((pos[i] + 59) / 60) - 1
                if(ln > lc) continue    # Line out of range?  Then go on.
                if(old[i] == substr(line[ln], cn, 1)) {
                        # Original matches... print the updated record.  First
                        # print the updated header line.
                        printf("%s|%s|%s%s%s %s", f[1], f[2], old[i], pos[i],
                                new[i], f[3])
                        for(j = 4; j <=fn; j++) printf("|%s", f[j])
                        printf("\n")
                        # Print sequence lines before the line containing the
                        # updated position.
                        for(j = 0; j < ln; j++) print line[j]
                        # Print the line with the modified position.
                        printf("%s%s%s\n", substr(line[ln], 1, cn - 1), new[i],
                                substr(line[ln], cn + 1))
                        # Print sequence lines after the line containing the
                        # updated position.
                        for(j = ln + 1; j < lc; j++) print line[j]
                }
        }

        # Reeet to process next record.
        gather = lc = 0
}
FNR == NR && NR > 1 {   # Read lines from position file (skipping header).
        id[++sc] = $1   # Id for input line sc
        sid[id[sc]]     # List of known Ids
        old[sc] = $2    # Original letter for input line sc
        pos[sc] = $3    # Position for input line sc
        new[sc] = $4    # Replacement letter for input line sc
        next}
/^>sp/ {# This is the 1st line of a new record...
        if(gather) check()      # Process previous record.
        nf = split($0, f, /[|]/)# Split 1st line of this record into fields.
        # If the Id in this line is in our list, gather the rest of this record.
        if(f[2] in sid) gather = 1
        next
}
gather {line[lc++] = $0
}
END {   # Process the last record...
        if(gather) check()
}' position sequence