#!/bin/ksh
awk -F% '
# Variables used:
# d1:   Diagnostic message 1 (! 3 _ in lf || np[4] fails to match ID[0-9].log)
# d2:   Diagnostic message 2 (np[3] > 0030 || np[3] not four decimal digits)
# d3:   Diagnostic message 3 (pattern not matched or matched more than once)
# fl:   Found Line (Contents of line 2 lines after last line matching
#       pattern.)
# flpc: Found Line % Count
# lf:   Last FILENAME (We cannot know that we have the last match in a
#       file until we hit the 1st line in the next file.  We save the
#       last value of FILENAME until we can print the results for this
#       file.)
# ln:   Line Number of line 2 lines after last line matching pattern.
# mc:   Match Count (Number of times we have found a line 2 lines after
#       a line matching pattern.)
# np[]: lf split by _ (There should always be 4 elements in this array.)
# ps:   Printable seq (np[3] if np[3] is four decimal digits; otherwise
#       "????".)
# seq:  Sequence number (Used to print lines noting missing sequence
#       numbers in the values of np[3] while 1 <= seq <= 30.)
function pr() {
# Usage: pr()
#    Verify the last FILENAME, print missing sequence numbers, and print
#    results of processing the last file.
        # Skip 1st call when we have not processed a file yet...
        if(lf == "") return
        # Verify filename format...
        if(split(lf, np, /_/) != 4)
                d1 = "  Filename should contain 3 underscores."
        else if(match(np[4], /^ID[0-9].log$/) != 1)
                d1 = "  " np[4] " does not match \"IDx.log\"."
        ps = (match(np[3], /^[0-9][0-9][0-9][0-9]$/) != 1) ? "????" : np[3]
        if(RSTART == 1) {
                # Print headers sequence numbers with no matching log files...`
                while(seq < np[3] && seq <= 30) printf("%04d -\n", seq++)
                seq = np[3] + 1
                if(np[3] > 30) d2 = "  " np[3] " out of range."
        } else  d2 = "  " np[3] " not four decimal digits."
        if(mc != 1) d3 = "  Pattern matched " mc " times."
        printf("%s - %-40s  %-80s  %4d%s%s%s\n", ps, lf, fl, flpc, d1, d2, d3)
        # Clear diagnostic messages, found line, and % count...
        d1 = d2 = d3 = fl = ""
        flpc = 0
}
BEGIN { seq = 1 }       # Set starting sequence #.
FNR == 1 {              # We have the first line of a new file.
        pr()            # Print results from previous file.
        lf = FILENAME   # Save FILENAME of current file.
        mc = 0          # Clear match count for this file.
}
/Percentage Completed/ {# We have a match.
        ln = FNR + 2    # Set line # for 2 lines later.
}
FNR == ln {             # We have a line 2 lines after a match.
        mc++            # Increment match count.
        fl = $0         # Save the line.
        flpc = NF - 1   # Save the number of % characters on this line.
        ln = 0          # Clear the line number.
}
END {   pr()            # Print results from last file processed.
}' $(ls *.log | sort -t_ -k3n -k4)      # Sort the log files to be processed.