$ cat infile                                                                                                                                                                                                                                 
<root>                                                                                                                                                                                                                                       
  <section status="ole-service">                                                                                                                                                                                                             
  <p service="OOO">XZZ</p>                                                                                                                                                                                                                   
  <p service="AAA">AAA BBC</p>                                                                                                                                                                                                               
  <p service="XYZ">XYZ</p></section>                                                                                                                                                                                                         

  <section status="ole-service">
  <p service="ABCD">ABC</p>
  <p service="BDE">B-DE (FGH)</p>
  <p service="XYZ">XY-YZ</p>
  <p service="MNO">M-NO</p>
  <p service="NOPQ">NOPQ</p>
  <p service="BCD">BCDE</p>
  <p service="ECM">eCM</p></section>
</root>
$ cat script.pl
#!/usr/bin/perl

use strict;
use warnings;
use XML::Twig;

{
        my $twig = XML::Twig->new(
                twig_handlers => {
                        'section[@status="ole-service"]' => sub {
                                my @childs = 
                                        map { $_->[0] } 
                                        sort { $a->[1] cmp $b->[1] } 
                                        map { [$_, do { my $t = $_->text; $t =~ s/\W//g; lc $t } ] } 
                                        $_->cut_children( 'p' );

                                for my $c ( @childs ) {
                                        $c->paste( last_child => $_ );
                                }
                        },
                },
                pretty_print => 'indented',
        );

        $twig->parsefile( shift );
        $twig->print;
}
$ perl-5.14.2 script.pl infile
<root>
  <section status="ole-service">
    <p service="AAA">AAA BBC</p>
    <p service="XYZ">XYZ</p>
    <p service="OOO">XZZ</p>
  </section>
  <section status="ole-service">
    <p service="ABCD">ABC</p>
    <p service="BCD">BCDE</p>
    <p service="BDE">B-DE (FGH)</p>
    <p service="ECM">eCM</p>
    <p service="MNO">M-NO</p>
    <p service="NOPQ">NOPQ</p>
    <p service="XYZ">XY-YZ</p>
  </section>
</root>