$ for file in scenario[1-4]; do cat -n "$file"; echo "----------"; done
     1  12345`English@|1@|perl is a scripting language@|English
     2  12345`English@|2@|Regular expression support is vast@|English
     3  12345`English@|3@|Has various items@|English
     4  12345`English@|4@|xml support is good@|English
----------
     1  12345`English@|1@|DC@|34@|4456@|Text needs to be concatenated@|English
     2  12345`English@|2@|FC@|36@|4455@|Text needs to be concatenated-1@|English
     3  12345`English@|3@|BC@|39@|4453@|Text needs to be concatenated-2@|English
----------
     1  12345`34445`English@|1@|desc text-1@|1000@|English
     2  12345`34445`English@|2@|desc text-2@|1000@|English
----------
     1  12345`34445`Japanese@|1@|text-1@|WE@|PRT@|F@|500@|Japanese
     2  12345`34445`Japanese@|2@|text-2@|WE@|PRT@|F@|500@|Japanese
----------
$ cat script.pl
use warnings;
use strict;

## Check arguments. Only one input file.
@ARGV == 1 or die qq[Usage: perl $0 file\n];

## Open input file. End if error.
open my $ifh, "<", $ARGV[0] or die qq[Cannot open input file for reading: $!\n];

## Read first line and set the position to the beginning.
my $first_line = <$ifh>;
seek $ifh, 0, 0 or die qq[ERROR processing input file: $!\n];

## Select scenario based in number of columns:
## 4 -> First scenario
## 7 -> Second scenario.
## 5 -> Third scenario.
## 8 -> Fourth scenario.

## Sample input is not clear. I suppose there are no headers.

my @f = split /@\|/, $first_line;
if ( @f == 4 ) {
        process_scenario_1();
}
elsif ( @f == 7 ) {
        process_scenario_2();
}
elsif ( @f == 5 ) {
        process_scenario_3();
}
elsif ( @f == 8 ) {
        process_scenario_4();
}
else {
        die qq[ERROR: Incorrect format of input file\n];
}

sub process_scenario_1 {
        my (@f, %sequence);

        while ( <$ifh> ) {
                next if /^\s*$/;
                chomp;
                @f = split /@\|/;
                $sequence{ $f[1] } = $f[2];
        } continue {
                if ( eof ) {
                        printf  "%s\n", 
                                join( qq[@|], 
                                        $f[0], 
                                        join( qq[ ], map( $sequence{ $_ }, sort { $a <=> $b } keys %sequence ) ), 
                                        $f[-1] );
                }
        }
}

sub process_scenario_2 {
        my (@f, %desc, %sequence);

        while ( <$ifh> ) {
                next if /^\s*$/;
                chomp;
                @f = split /@\|/;
                push @{ $desc{ $f[1] } }, @f[2..4];
                $sequence{ $f[1] } = $f[5];
        } continue {
                if ( eof ) {
                        printf "%s\n",
                                join( qq[@|],
                                        $f[0],
                                        join( qq[@|], map( @{ $desc{ $_ } }, sort { $a <=> $b } keys %desc ) ),
                                        join( qq[ ], map( $sequence{ $_ }, sort { $a <=> $b } keys %sequence ) ),
                                        $f[-1] );
                }
        }
}

sub process_scenario_3 {
        my (@f, %sequence);

        while ( <$ifh> ) {
                next if /^\s*$/;
                chomp;
                @f = split /@\|/;
                $sequence{ $f[1] } = $f[2];
        } continue {
                if ( eof ) {
                        printf  "%s\n", 
                                join( qq[@|], 
                                        $f[0], 
                                        join( qq[ ], map( $sequence{ $_ }, sort { $a <=> $b } keys %sequence ) ), 
                                        @f[-2,-1] );
                }
        }
}

sub process_scenario_4 {
        my (@f, %sequence);

        while ( <$ifh> ) {
                next if /^\s*$/;
                chomp;
                @f = split /@\|/;
                $sequence{ $f[1] } = $f[2];
        } continue {
                if ( eof ) {
                        printf  "%s\n", 
                                join( qq[@|], 
                                        $f[0], 
                                        @f[3..5],
                                        join( qq[ ], map( $sequence{ $_ }, sort { $a <=> $b } keys %sequence ) ), 
                                        @f[-2,-1] );
                }
        }

}
$ perl script.pl
Usage: perl script.pl file
$ for file in scenario[1-4]; do printf "%s\n" "Command -> perl script.pl $file"; printf "%s\n" "Output ->"; perl script.pl "$file"; done 
Command -> perl script.pl scenario1
Output ->
12345`English@|perl is a scripting language Regular expression support is vast Has various items xml support is good@|English
Command -> perl script.pl scenario2
Output ->
12345`English@|DC@|34@|4456@|FC@|36@|4455@|BC@|39@|4453@|Text needs to be concatenated Text needs to be concatenated-1 Text needs to be concatenated-2@|English
Command -> perl script.pl scenario3
Output ->
12345`34445`English@|desc text-1 desc text-2@|1000@|English
Command -> perl script.pl scenario4
Output ->
12345`34445`Japanese@|WE@|PRT@|F@|text-1 text-2@|500@|Japanese