$ cat infile
Monday                                                                                                                                                                              
Tuesday                                                                                                                                                                             
;Wednesday                                                                                                                                                                          
Thursday                                                                                                                                                                            
;Friday                                                                                                                                                                             
;Saturday                                                                                                                                                                           
Sunday
$ cat script.sed
#!/bin/sed -nf                                                                                                                                                                      
                                                                                                                                                                                    
## First line: copy it to 'hold space' and read next one.                                                                                                                           
1 { h ; n }                                                                                                                                                                         
                                                                                                                                                                                    
## Lines beginning with ';': Append to 'hold space'. If last line, skip to                                                                                                          
## label 'l' to print rest of content, else begin next cycle.                                                                                                                       
/^;/ { H ; $ bl ; b }                                                                                                                                                               
                                                                                                                                                                                    
## A line without ';' at the beginning. Print lines saved in 'hold 'space'                                                                                                          
## removing '\n' chars and print it.                                                                                                                                                
:l                                                                                                                                                                                  
x ; s/\n;/;/g ; p                                                                                                                                                                   
                                                                                                                                                                                    
## Last line: If begins with ';' it will have been printed before, else take                                                                                                        
## it from 'hold space' and print it.                                                                                                                                               
$ { x ; /^;/! p }
$ ./script.sed infile
Monday
Tuesday;Wednesday
Thursday;Friday;Saturday
Sunday