awk '
        /Start/ { print; next; }                # header; just as it
        {
                ns = split( $2, st, "," );
                ne = split( $3, en, "," );

                if( ns != ne )
                {
                        printf( "count mismatch; skipped\n" );
                        next;
                }

                delete joined;               # ditch array built for last record
                for( i = 1; i <= ns; i++ )
                        joined[i] = sprintf( "%05d %05d", st[i], en[i] );       # 0s force proper sort order

                asort( joined )             # sort the array using array value

                printf( "%s ", $1 );                    # a,b,c etc. from col 1 of input
                for( i = 1; i <= ns; i++ )
                {
                        printf( "%d%s", joined[i]+0, i == ns ? " " : "," );     # print start column
                        gsub( ".* ", " ", joined[i] );  # delete start number from the pair
                        oe[i] = joined[i]+0;            # save end column pair
                }

                for( i = 1; i <= ns; i++ )              # print end column
                        printf( "%d%s", oe[i]+0, i == ns ? "\n" : "," );
        }
' input-file