#!/usr/bin/perl

use strict;
use warnings;

my @if = ();    # array of input files
my $ignore_first_line = 1; #

# open all files
while ( <STDIN> ) {
        chomp;
        if ( -r $_ ) {
                my $index = @if;
                open( $if[ $index ]->{ handle }, "<", $_) or die "Couldn't open file $_: $!";
                $if[ $index ]->{ name } = $_; # save the filename
                $if[ $index ]->{ F }[0] = -1; # set default pos value for this file to "unread"
                if ( $ignore_first_line ) {
                        my $dummy_fh = $if[ $index ]->{ handle };
                        my $dummy = < $dummy_fh >;
                }
        }
}

# print the header
print "chr\tPosition";
for ( 0 .. $#if ) {
        print "\t$if[$_]->{name}";
}
print "\n";

my $pos = 0;    # pos indicates which record we're dealing with

# let's loop the files until all are read thru
while ( 1 ) {
        my $ofc = 0;    # open filehandle count
        my $str = "";   # build the infoline here
        my $ref = undef;
        ++$pos;                 # increase the line position

        # loop thru all files
        for my $index ( 0 .. $#if ) {
                if ( defined ( $if[$index]->{handle} ) ) { # check if the file is open and we can read from it
                        ++$ofc;
                        if ( $if[$index]->{F}[0] < $pos ) {
                                my $handle = $if[$index]->{handle}; # save filehandle to a temp variable
                                if ( defined ( $if[$index]->{line} = <$handle> ) ) {
                                        @{$if[$index]->{F}} = split(/\s/, $if[$index]->{line});
                                        $if[$index]->{F}[0] =~ s/.*?(\d+)/$1/; # save only the number, eg. from cnvi0000003
                                }
                                else {
                                        $if[$index]->{handle} = undef; # close filehandle
                                }
                        }

                        if ( defined ( $if[$index]->{handle} ) and $if[$index]->{F}[0] == $pos ) {
                                # according to position we'll print this data now
                                # also save a reference to the data so we can print
                                # character and position later
                                $ref = $if[$index]->{F};
                                $str .= "\t" . $if[$index]->{F}[3];
                        }
                        else {
                                $str .= "\t"; # empty record
                        }

                }
                else {
                        $str .= "\t"; # empty record
                }
        }

        if ( defined ( $ref ) ) {
                print "$$ref[1]\t$$ref[2]$str\n";
        }

        last unless $ofc;
}