Mojo::IOLoop(3pm)					User Contributed Perl Documentation					 Mojo::IOLoop(3pm)

NAME

       Mojo::IOLoop - Minimalistic reactor for non-blocking TCP clients and servers

SYNOPSIS

	 use Mojo::IOLoop;

	 # Listen on port 3000
	 Mojo::IOLoop->server({port => 3000} => sub {
	   my ($loop, $stream) = @_;

	   $stream->on(read => sub {
	     my ($stream, $chunk) = @_;

	     # Process input
	     say $chunk;

	     # Got some data, time to write
	     $stream->write('HTTP/1.1 200 OK');
	   });
	 });

	 # Connect to port 3000
	 my $id = Mojo::IOLoop->client({port => 3000} => sub {
	   my ($loop, $err, $stream) = @_;

	   $stream->on(read => sub {
	     my ($stream, $chunk) = @_;

	     # Process input
	     say "Input: $chunk";
	   });

	   # Write request
	   $stream->write("GET / HTTP/1.1

");
	 });

	 # Add a timer
	 Mojo::IOLoop->timer(5 => sub {
	   my $loop = shift;
	   $loop->remove($id);
	 });

	 # Start loop if necessary
	 Mojo::IOLoop->start unless Mojo::IOLoop->is_running;

DESCRIPTION

       Mojo::IOLoop is a very minimalistic reactor based on Mojo::Reactor, it has been reduced to the absolute minimal feature set required to
       build solid and scalable non-blocking TCP clients and servers.

       Optional modules EV, IO::Socket::INET6 and IO::Socket::SSL are supported transparently and used if installed. Individual features can also
       be disabled with the "MOJO_NO_IPV6" and "MOJO_NO_TLS" environment variables.

       A TLS certificate and key are also built right in to make writing test servers as easy as possible. Also note that for convenience the
       "PIPE" signal will be set to "IGNORE" when Mojo::IOLoop is loaded.

       See Mojolicious::Guides::Cookbook for more.

ATTRIBUTES

       Mojo::IOLoop implements the following attributes.

   "client_class"
	 my $class = $loop->client_class;
	 $loop	   = $loop->client_class('Mojo::IOLoop::Client');

       Class to be used for opening TCP connections with the "client" method, defaults to Mojo::IOLoop::Client.

   "lock"
	 my $cb = $loop->lock;
	 $loop	= $loop->lock(sub {...});

       A callback for acquiring the accept mutex, used to sync multiple server processes. The callback should return true or false. Note that
       exceptions in this callback are not captured.

	 $loop->lock(sub {
	   my ($loop, $blocking) = @_;

	   # Got the accept mutex, start listening
	   return 1;
	 });

   "max_accepts"
	 my $max = $loop->max_accepts;
	 $loop	 = $loop->max_accepts(1000);

       The maximum number of connections this loop is allowed to accept before shutting down gracefully without interrupting existing connections,
       defaults to 0. Setting the value to 0 will allow this loop to accept new connections indefinitely.

   "max_connections"
	 my $max = $loop->max_connections;
	 $loop	 = $loop->max_connections(1000);

       The maximum number of parallel connections this loop is allowed to handle before stopping to accept new incoming connections, defaults to
       1000.  Setting the value to 0 will make this loop stop accepting new connections and allow it to shut down gracefully without interrupting
       existing connections.

   "reactor"
	 my $reactor = $loop->reactor;
	 $loop	     = $loop->reactor(Mojo::Reactor->new);

       Low level event reactor, usually a Mojo::Reactor::Poll or Mojo::Reactor::EV object.

	 # Watch handle for I/O events
	 $loop->reactor->io($handle => sub {
	   my ($reactor, $writable) = @_;
	   say $writable ? 'Handle is writable' : 'Handle is readable';
	 });

   "server_class"
	 my $class = $loop->server_class;
	 $loop	   = $loop->server_class('Mojo::IOLoop::Server');

       Class to be used for accepting TCP connections with the "server" method, defaults to Mojo::IOLoop::Server.

   "stream_class"
	 my $class = $loop->stream_class;
	 $loop	   = $loop->stream_class('Mojo::IOLoop::Stream');

       Class to be used by "client" and "server" methods for I/O streams, defaults to Mojo::IOLoop::Stream.

   "unlock"
	 my $cb = $loop->unlock;
	 $loop	= $loop->unlock(sub {...});

       A callback for releasing the accept mutex, used to sync multiple server processes. Note that exceptions in this callback are not captured.

METHODS

       Mojo::IOLoop inherits all methods from Mojo::Base and implements the following new ones.

   "client"
	 my $id
	   = Mojo::IOLoop->client(address => '127.0.0.1', port => 3000, sub {...});
	 my $id = $loop->client(address => '127.0.0.1', port => 3000, sub {...});
	 my $id = $loop->client({address => '127.0.0.1', port => 3000}, sub {...});

       Open TCP connection with "client_class", which is usually Mojo::IOLoop::Client, takes the same arguments as "connect" in
       Mojo::IOLoop::Client.

	 # Connect to localhost on port 3000
	 Mojo::IOLoop->client({port => 3000} => sub {
	   my ($loop, $err, $stream) = @_;
	   ...
	 });

   "delay"
	 my $delay = Mojo::IOLoop->delay;
	 my $delay = $loop->delay;
	 my $delay = $loop->delay(sub {...});

       Get Mojo::IOLoop::Delay object to synchronize events and subscribe to event "finish" in Mojo::IOLoop::Delay if optional callback is
       provided.

	 # Synchronize multiple events
	 my $delay = Mojo::IOLoop->delay(sub { say 'BOOM!' });
	 for my $i (1 .. 10) {
	   $delay->begin;
	   Mojo::IOLoop->timer($i => sub {
	     say 10 - $i;
	     $delay->end;
	   });
	 }

	 # Wait for events if necessary
	 $delay->wait unless Mojo::IOLoop->is_running;

   "generate_port"
	 my $port = Mojo::IOLoop->generate_port;
	 my $port = $loop->generate_port;

       Find a free TCP port, this is a utility function primarily used for tests.

   "is_running"
	 my $success = Mojo::IOLoop->is_running;
	 my $success = $loop->is_running;

       Check if loop is running.

	 exit unless Mojo::IOLoop->is_running;

   "one_tick"
	 Mojo::IOLoop->one_tick;
	 $loop->one_tick;

       Run reactor until an event occurs or no events are being watched anymore. Note that this method can recurse back into the reactor, so you
       need to be careful.

   "recurring"
	 my $id = Mojo::IOLoop->recurring(0 => sub {...});
	 my $id = $loop->recurring(3 => sub {...});

       Create a new recurring timer, invoking the callback repeatedly after a given amount of time in seconds.

	 # Invoke as soon as possible
	 Mojo::IOLoop->recurring(0 => sub { say 'Reactor tick.' });

   "remove"
	 Mojo::IOLoop->remove($id);
	 $loop->remove($id);

       Remove anything with an id, connections will be dropped gracefully by allowing them to finish writing all data in their write buffers.

   "server"
	 my $id = Mojo::IOLoop->server(port => 3000, sub {...});
	 my $id = $loop->server(port => 3000, sub {...});
	 my $id = $loop->server({port => 3000}, sub {...});

       Accept TCP connections with "server_class", which is usually Mojo::IOLoop::Server, takes the same arguments as "listen" in
       Mojo::IOLoop::Server.

	 # Listen on port 3000
	 Mojo::IOLoop->server({port => 3000} => sub {
	   my ($loop, $stream, $id) = @_;
	   ...
	 });

   "singleton"
	 my $loop = Mojo::IOLoop->singleton;

       The global Mojo::IOLoop singleton, used to access a single shared loop object from everywhere inside the process.

	 # Many methods also allow you to take shortcuts
	 Mojo::IOLoop->timer(2 => sub { Mojo::IOLoop->stop });
	 Mojo::IOLoop->start;

   "start"
	 Mojo::IOLoop->start;
	 $loop->start;

       Start the loop, this will block until "stop" is called or no events are being watched anymore.

	 # Start loop only if it is not running already
	 Mojo::IOLoop->start unless Mojo::IOLoop->is_running;

   "stop"
	 Mojo::IOLoop->stop;
	 $loop->stop;

       Stop the loop, this will not interrupt any existing connections and the loop can be restarted by running "start" again.

   "stream"
	 my $stream = Mojo::IOLoop->stream($id);
	 my $stream = $loop->stream($id);
	 my $id     = $loop->stream($stream);

       Get Mojo::IOLoop::Stream object for id or turn object into a connection.

	 # Increase inactivity timeout for connection to 300 seconds
	 Mojo::IOLoop->stream($id)->timeout(300);

   "timer"
	 my $id = Mojo::IOLoop->timer(5 => sub {...});
	 my $id = $loop->timer(5 => sub {...});
	 my $id = $loop->timer(0.25 => sub {...});

       Create a new timer, invoking the callback after a given amount of time in seconds.

	 # Invoke as soon as possible
	 Mojo::IOLoop->timer(0 => sub { say 'Next tick.' });

DEBUGGING

       You can set the "MOJO_IOLOOP_DEBUG" environment variable to get some advanced diagnostics information printed to "STDERR".

	 MOJO_IOLOOP_DEBUG=1

SEE ALSO

       Mojolicious, Mojolicious::Guides, <http://mojolicio.us>.

perl v5.14.2							    2012-09-05							 Mojo::IOLoop(3pm)