UNIX for Dummies Questions & Answers

I have a unique situation here which looks easier at first but I am not able to solve it.
# SSort UNIX 10/14/2005 10/13/2010 "tox" "9000/800" 16 * * * V849-6-1
# SSort UNIX 11/31/1996 11/02/2010 "tox" "9000/800" 16 * * * W237-S-2

I have a text file with two or multiple values like this and what I am trying to do is compare these lines and just keep the line with the latest date on it.
Note: every line have two dates but the one we have to look at is the second date
10/13/2010 in first line and 11/02/2010
in second line.
Any way to do it using unix commands?
I can compare two dates with this command and print the required one
if the file name is tmp I can do this and get the latest date
cat tmp|awk '{print $5}'|sort -t '|' -k3n -k1n -k2n|sed '$!d'
but what I want is the entire line like this
# SSort UNIX 11/31/1996 11/02/2010 "tox" "9000/800" 16 * * * W237-S-2
not only date value.

assuming the fields 6 and 7 can be used as 'key' fields uniquely identifying records/lines...

nawk -f par.awk myFile

par.awk:

Code:

{
  split($5, datA, "/")
  dat=datA[3] datA[1] datA[2]
  idx = $6 SUBSEP $7

  if (dat > arrD[idx]) {
     arrD[idx]=dat
     arrV[idx]=$0
  }
}
END {
  for (i in arrV)
    print arrV[i]
}

Or if you don't care about uniqueness and keys and just one to get ONE line:

Code:

{
  split($5, datA, "/")
  dat=datA[3] datA[1] datA[2]
  idx = $6 SUBSEP $7

  if (dat > maxD) {
     maxD=dat
     line=$0
  }
}
END {
  print line
}