UNIX for Advanced & Expert Users

 awk -v remove=XMPP_ec2-184-2-2-2 '
        /define host/ {                 # start of new block; print last section
                if( snarfed )
                        printf( "%s", snarfed );   # buffer already has trailing newline so printf preferred

                snarfed = $0 "\n";              # start capture
                drop = 0;
                next;
        }

        /host_name/ {                   # check to see if unwanted target
                if( $2 == remove )      # if it is then
                {
                        snarfed = "";      # ditch what we had
                        drop= 1;   # prevent picking up more til next section
                        next;
                }
        }

        !drop {                  # if we are snarfing from current section
                snarfed = snarfed $0 "\n";      # add next line
                next;
        }
        END {                           # must do one last for the last buffered section
                if( snarfed )
                        print snarfed;
        }
' input-file >output-file